The next small thing!

Jood · Nov 14th 2020

Leider sind die fehlenden Teile für meinen Triple X-Pander immer noch nicht gekommen,

daher musste ich mich anderweitig beschäftigen.

Resultat, die ersten Prototypen des Tiny Reset Rev.1a sind nicht nur fertig geworden, sie

funktionieren sogar, obwohl hier ein alter Sack Dinge lötet die er kaum noch sehen kann!

Der Tiny Reset Rev.1a macht genau das was der Name vermuten lässt, Restore wird

überwacht, und abhängig davon ein Reset ausgelöst.

Zusätzlich wird noch ein WS2812b LED-Stripe angesteuert, im Moment aber noch ohne

Farbwechsel oder ähnliche Spielereien.

In erster Linie ist die Entwicklung für meine C64 (meist mit Superkernal)

Funktionen:

- LED-Stripe (könnte auch blau leuchten)

- 3 Sec. Druck auf Restore löst einen Reset aus.

- Doppel-Tap auf Restore ruft das Superkernal auf (Doppel-Reset)

Im Bild Rev.1a, die Platine passt gut in 250407/250425/250466/250469, bei meinem

Ultimate muss ich noch schauen.

Und im einbauten Zustand, die Platine wird einfach auf den Tastatur-Header gesteckt,

die Zastatur dann auf die Platine.

Zusätzlich ist noch ein Anschluss für die Board-LED vorhanden, dieser kann wahlweise

auch von hinten bestückt werden (passt besser bei 250407/250425/250466), oder

von vorne (250469), beim Ultimate werde ich den Anschluss wohl fehlen lassen.

Und eingebaut in ein 250469, der LED-Header diesmal auf der anderen Seite.

Platzprobleme gibt es lediglich bei C64 mit Blechabdeckungen, ich überlege noch ob ich

das was anpasse.

Mfg Jood

Oh verdammt...

Das Ganze sollte in "heute so gebastelt", kann bitte ein MOD verschieben ?

Danke

Jood · Nov 14th 2020

So...

Hab den Tiny Reset nun auch in mein Assy 250466 eingebaut, sieht richtig gut aus.

Hier ohne LED-Stripe (in der Software ist es trotzdem noch drin).

Mfg Jood

Jood · Nov 15th 2020

Einen hab ich noch...

Zu guter letzt habe ich noch einen Tiny-Reset in meinen U64e einbaut, auch hier passt die Platine wunderbar.

Weil ein U64e keinen Superkernal hat ist die Funktion (Double-Tap) geändert und die Farbumschaltung damit

realisiert.

Also 3 Sec. Restore = RESET, Double-Tap auf Restore ändert die Farbe der LED-Stripe. Ich hab da im Moment

Lime, DarkSkyBlue, Rot und AUS drauf, die jeweils letzte Einstellung wird im EEProm gespeichert.

Natürlich wären hier auch Effekte wie Lauflicht möglich:

https://www.tweaking4all.com/h…druino-led-strip-effects/

Aber mir ist das zu unruhig!

Rechts am Tastatur-Header, die schwarze Platine passt gut zum U64e-Board,

zum fotografieren ist Schwarz auf Schwarz natürlich eher ungünstig!

Jood · Nov 21st 2020

Eine wichtige Lieferung für meine Neues Projekt: Dual-Port Weiche ist immer noch nicht gekommen, also habe ich Zeit für andere Dinge.

Unter anderem habe ich die Firmware für dieses Projekt überarbeitet, an der grundlegenden Funktion ändert sich aber nichts.

Die Firmware gibt es in 2 Versionen:

1. Ausgelegt für den C64 (getestet mit 250407/250425/250466/250469) mit Superkernal

- Langer Druck auf (3. Sekunden) löst einen Reset aus

- Doppel-Tab auf Reset ruft das Superkernal auf, hier wird einfach ein Doppel-reset ausgelöst.

- Zusätzlich liegt auf dem Header noch ein LED-Stripe WS2812b mit 21 LED's, der einfach nur Grün (CRGB::Lime) leuchtet, die Stromaufnahme ist auf ca. 90mA begrenzt (gemesssen).

C

#include <FastLED.h> //https://github.com/FastLED/FastLED
#include <ClickButton.h> //https://github.com/marcobrianza/ClickButton
//Constants
#define NUM_LEDS 21 //Const (Number of LED's)
#define DISABLE_LED 20 //Const (switch off last LED)
#define DATA_PIN PB0 //LED-Stripe (Pin 5 - MOSI)
#define RESERVE1 PB1 //Reserve (Pin 6 - MISO)
#define RESET_OUT PB2 //Reset to C64 (Pin 7 - SCK)
#define POWER_LED PB3 //Power LED C64 (Pin 2)
#define RESTORE_PIN PB4 //Restore von C64 (Pin 3)
#define WAIT_TIME 100 //Const Delay for Reset
#define BRIGHTNESS 80 //led brightness (limit power to 90 mA)
CRGB leds[NUM_LEDS]; //LED-Stripe, number of LED's
CRGB ledColor = CRGB::Lime; //LED-Stripe, current Color (RGB)
ClickButton Restore(RESTORE_PIN, LOW); //Restore Button
void setup() {
pinMode(RESET_OUT, INPUT); //Input without pullup, emulate open collector
pinMode(RESTORE_PIN, INPUT); //Input without pullup, Restore from C64
pinMode(POWER_LED, OUTPUT); //Output, Power LED for C64
digitalWrite(POWER_LED, LOW); //Power LED an
Restore.debounceTime = 35; //Debounce timer in ms
Restore.multiclickTime = 250; //Time limit for multi clicks
Restore.longClickTime = 3000; //time until "held-down clicks" register
FastLED.addLeds<WS2812B, DATA_PIN, RGB>(leds, NUM_LEDS);
FastLED.setBrightness(BRIGHTNESS); //Set led brightness (save power)
FadeIn(ledColor);
}
void wait(uint32_t period) {
uint32_t time_now = millis();
while(millis() < time_now + period){
//wait approx. [period] ms
}
}
void ShowColor(byte r, byte g, byte b){
for (int i = 0; i < NUM_LEDS; i++) {
//switch of LED, center light on C64
if (i != DISABLE_LED) {
leds[i] = CRGB(g, r, b);
} else leds[i] = CRGB::Black;
}
FastLED.show();
}
void FadeIn(CRGB color){
float r, g, b;
for(int k = 0; k < 256; k=k+1) {
r = (k/256.0)*color.red;
g = (k/256.0)*color.green;
b = (k/256.0)*color.blue;
ShowColor(r, g, b);
}
}
void FadeOut(CRGB color){
float r, g, b;
for(int k = 255; k >= 0; k=k-2) {
r = (k/256.0)*color.red;
g = (k/256.0)*color.green;
b = (k/256.0)*color.blue;
ShowColor(r, g, b);
}
}
void loop() {
Restore.Update();
switch (Restore.clicks) {
case 2: //doubleClick
for (int i=0; i <= 1; i++) {
pinMode(RESET_OUT, OUTPUT);
wait(WAIT_TIME);
pinMode(RESET_OUT, INPUT);
wait(WAIT_TIME);
}
break;
case -1: //longpress
pinMode(RESET_OUT, OUTPUT);
while (!digitalRead(RESTORE_PIN)) {
digitalWrite(POWER_LED, !digitalRead(POWER_LED));
wait(WAIT_TIME);
}
digitalWrite(POWER_LED, LOW);
pinMode(RESET_OUT, INPUT);
Restore.clicks = 0;
wait(WAIT_TIME);
break;
default:
break;
}
}

Display More

2. Eine Version für mein Ultimate 64e, welches in einem transparenten PixelWizard Gehäuse sitzt.

- Langer Druck auf (3. Sekunden) löst einen Reset aus

- da im Ultimate kein Superkernal sitzt habe den Doppel-Tab mit eine Farbumschaltung für den LED-Stripe belegt.

C

#include <EEPROM.h>
#include <FastLED.h> //https://github.com/FastLED/FastLED
#include <ClickButton.h> //https://github.com/marcobrianza/ClickButton
//Constants
#define NUM_LEDS 21 //Const (Number of LED's)
#define DISABLE_LED 0 //Const (switch off last LED)
#define DATA_PIN 0 //LED-Stripe (PB0, Pin 5 - MOSI)
#define RESERVE1 1 //Reserve (PB1, Pin 6 - MISO)
#define RESET_OUT 2 //Reset to C64 (PB2, Pin 7 - SCK)
#define POWER_LED 3 //Power LED C64 (PB3, Pin 2)
#define RESTORE_PIN 4 //Restore von C64 (PB4, Pin 3)
#define WAIT_TIME 100 //Const Delay for Reset
#define BRIGHTNESS 100 //led brightness, save Power
#define EEPROM_ADDR 0 //Memory - Configuration.
byte ledIndex = 0;
CRGB leds[NUM_LEDS]; //LED-Stripe, number of LED's
CRGB ledColor = CRGB::Lime; //Current LED Color
ClickButton Restore(RESTORE_PIN, LOW); //Restore Button
void setup() {
pinMode(RESET_OUT, INPUT); //Input without pullup, emulate open collector
pinMode(RESTORE_PIN, INPUT); //Input without pullup, Restore from C64
pinMode(POWER_LED, OUTPUT); //Output, Power LED for C64
digitalWrite(POWER_LED, LOW); //Power LED an
Restore.debounceTime = 35; //Debounce timer in ms
Restore.multiclickTime = 250; //Time limit for multi clicks
Restore.longClickTime = 3000; //time until "held-down clicks" register
FastLED.addLeds<WS2812B, DATA_PIN, RGB>(leds, NUM_LEDS);
FastLED.setBrightness(BRIGHTNESS); //Set led brightness (save power)
SetColor(EEPROM.read(EEPROM_ADDR));
FadeIn(ledColor);
}
void wait(uint32_t period) {
uint32_t time_now = millis();
while(millis() < time_now + period){
//wait approx. [period] ms
}
}
void SetColor(byte index){
if ((index >= 0) && (index <= 4)){
ledIndex = index;
} else ledIndex = 0;
EEPROM.update(EEPROM_ADDR, ledIndex);
switch (ledIndex){
case 0:
ledColor = CRGB::Lime;
FadeIn(ledColor);
break;
case 1:
ledColor = CRGB::Red;
FadeIn(ledColor);
break;
case 2:
ledColor = CRGB::DeepSkyBlue;
FadeIn(ledColor);
break;
case 3:
ledColor = CRGB::Yellow;
FadeIn(ledColor);
break;
case 4:
ledColor = CRGB::Black;
break;
}
}
void ShowColor(byte r, byte g, byte b){
for (int i = 0; i < NUM_LEDS; i++) {
//switch of LED, center light on C64
if (i != DISABLE_LED) {
leds[i] = CRGB(g, r, b);
} else leds[i] = CRGB::Black;
}
FastLED.show();
}
void FadeIn(CRGB color){
float r, g, b;
for(int k = 0; k < 256; k=k+1) {
r = (k/256.0)*color.red;
g = (k/256.0)*color.green;
b = (k/256.0)*color.blue;
ShowColor(r, g, b);
}
}
void FadeOut(CRGB color){
float r, g, b;
for(int k = 255; k >= 0; k=k-2) {
r = (k/256.0)*color.red;
g = (k/256.0)*color.green;
b = (k/256.0)*color.blue;
ShowColor(r, g, b);
}
}
void loop() {
Restore.Update();
switch (Restore.clicks) {
case 2: //doubleClick
Restore.clicks = 0;
FadeOut(ledColor);
SetColor(ledIndex+1);
break;
case -1: //longpress
Restore.clicks = 0;
pinMode(RESET_OUT, OUTPUT);
while (!digitalRead(RESTORE_PIN)) {
digitalWrite(POWER_LED, !digitalRead(POWER_LED));
wait(WAIT_TIME);
}
digitalWrite(POWER_LED, LOW);
pinMode(RESET_OUT, INPUT);
wait(WAIT_TIME);
break;
default:
break;
}
}

Display More

Falls Interesse besteht packe ich das Projekt (KiCAD) auch noch hier rein.

Mfg Jood

-micky · Nov 21st 2020

Ja, interesse besteht. Nur wo bekomme ich eine Platine her?

Micky

Jood · Nov 21st 2020

Ich hatte ja bereits erwähnt das das Ding neben der Reset/Superkernal-Funktion, noch eine LED-Stripe steuern kann.

Was haltet ihr davon (rechts im Bild übrigens mein Ultimate 64e) ?

Könnte neben der einfachen Beleuchtung noch mit in den Tiny Reset!

Mfg Jood

Jood · 2020-11-28T14:07:46+01:00

Kleine Video gemacht, Qualität ist nicht so gut, aber man sieht was.

[External Media: https://youtu.be/YYRA7nGCU94]

Mfg Jood

VomitOnLino · 2020-11-28T14:16:21+01:00

Ja, da bin ich auf jeden Fall interessiert.

Habe zwar einen Reset-taster (ohne Bohren) angeloetet aber das ist nochmal ein ganzes Stueck eleganter.