>= Abfrage im Dezimal-Mode

Ingo · 14. Juni 2019

Hallo,

ich habe zwei Werte mit jeweils 3 Bytes im Dezimal-Mode und möchte wissen, ob neuer_wert >= alter_wert ist.
Dabei ist das erste Byte das HI, dann kommt das MID und dann das LO Byte.
Also z.B. die Zahlen (alter_wert=14823 und neuer_wert=15656)

alter_wert .byte $01,$48,$23
neuer_wert .byte $01,$56,$56

Wie ist das am elegantesten zu bewerkstelligen?

alx · 14. Juni 2019

Nur ADC und SBC unterdtützen den Dezimal-Modus.
Also setzte D und nimm SBC anstelle von CMP zum vergleich.
Hier ein paar infos darüber:
http://6502.org/tutorials/decimal_mode.html

Ingo · 14. Juni 2019

Also wenn man nur Ziffern zwischen 0 und 9 verwendet, müsste es doch mit CMP auch funktionieren:
(Hab gerade was zusammengebastelt)

Code

*= $c000
jmp start
alter_wert .byte $01,$36,$73
neuer_wert .byte $02,$12,$82
start
lda neuer_wert
cmp alter_wert
bcc exit ;< -> 0 rueckgeb.
beq s1
lda #$01 ;> -> 1 rueckgeb.
rts
s1
;Hier =
lda neuer_wert+1
cmp alter_wert+1
bcc exit ;< -> 0 rueckgeb.
beq s2
lda #$01 ;> -> 1 rueckgeb.
rts
s2
;Hier =
lda neuer_wert+2
cmp alter_wert+2
bcc exit ;< -> 0 rueckgeb.
lda #$01 ;> -> 1 rueckgeb.
rts
exit
lda #$00
rts

Alles anzeigen

alx · 14. Juni 2019

Stimmt, wenn dir das ergebnis egal ist dann geht das auch, aber dies is kürzer:

Code

lda neuer_wert+2
cmp alter_wert+2
lda neuer_wert+1
sbc alter_wert+1
lda neuer_wert+0
sbc alter_wert+0
bcc neu_ge_alt

Ingo · 14. Juni 2019

Funktioniert - cool. Danke!

Merlin_The7thSign · 14. Juni 2019

Noch etwas kürzer geht's mit 'ner Schleife:

Code

ldx #$FD
next
lda neuer_wert-$FD,X
cmp alter_wert-$FD,X
bne exit
inx
bne next
exit
rts ; C set, wenn neu >= alt

JeeK · 18. Juni 2019

Zitat von Merlin_The7thSign

Noch etwas kürzer geht's mit 'ner Schleife:

Gefällt mir auch insofern gut, weil ja nicht alle Bytes durch gegangen werden müssen, also bei der ersten Abweichung das Ergebnis feststeht (die Schleife verlassen wird) - im Vergleich zu alx' Ansatz. Wenn die Werte sich immer nur geringfügig (im letzten, niederwertigsten Byte) unterscheiden, dann hat die Schleifenvariante zumindest von der Laufzeit mehr Overhead. Das muss man dann abwägen, ob Platz oder Geschwindigkeit der Vorzug zu geben ist.

alx · 18. Juni 2019

Zitat von JeeK

Das muss man dann abwägen, ob Platz oder Geschwindigkeit der Vorzug zu geben ist.

Und ob man ein freies index register hat. Und wenn du das nicht >1000 mal pro sekunde durchlauefst wird der geschwindigkeits unterschied (worst/best case loop / fixed) nicht relevant sein. (Und dafür ist auch noch die frage ist auch wie oft die werte gleich seien werden, denn das ist der worst case der loop.)