Möglicherweise ist es eine Magicnumber?
Ah, vielen Dank für die Infos! Der Quelltext ist sehr nützlich, das bedeutet nämlich, dass ich statt der $11 (die ich im Beispielbild als Escape-Code gefunden habe) auch irgendeinen anderen verwenden kann. Eine Optimierung dieses Codes halte ich sowieso für überbewertet, weshalb ich in GoDot (und dann in Zukunft sicher auch im Saver für Pixel Perfect) einfach $AD verwende. Liegt bei meinem Namen irgendwie nahe, hehe... 
Meine Encodierungsroutine erscheint mir kürzer. Hier der Code:
; ----------------------------------------- Compress algorithm
; indicator, counter, byte (counter counts minus 1)
pack bit packflag ; Flag, ob gepackt werden soll oder nicht
bmi wl4
jmp bsout ; dann eben nicht...
wl4 cmp gbyte ; letztes Byte (startet mit $00 als Initwert)
beq incr
p255 pha ; laufendes Byte
lda cnt ; Zähler, beim ersten Mal 0
beq wl1
cmp #$ff ; maximum compress?
beq wl0 ; ja, Code-Sequenz ausgeben
cmp #4 ; Zähler größer als 3?
bcs wl0 ; ja, Code-Sequenz ausgeben
lda gbyte ; letztes Byte gleich Escape-Code?
cmp #$11 ; (war im File also $11)
bne wl2 ; nein, dann einfach ausgeben (und Zähler um 1 erhöhen)
; sonst out: $11 $01 $11
wl0 lda #$11 ; out: $11
jsr bsout
dec cnt ; Zähler minus 1
lda cnt ; out: counter
jsr bsout
lda #1 ; jetzt Zähler auf 1
sta cnt
lda gbyte ; out: Byte
wl2 jsr bsout
dec cnt ; wenn Zähler=1 war, weiter:
bne wl2
wl1 pla ; laufendes Byte zu letztem Byte wandeln
sta gbyte
incr inc cnt ; Zähler erhöhen
lda cnt ; 255 erreicht?
cmp #$ff ; könnte man weglassen, dann würden 256 Bytes kodiert (oder?)
bne wl3 ; nein, fertig
lda gbyte ; sonst: Code-Sequenz ausgeben
jsr p255
dec cnt ; Zähler korrigieren
wl3 rts ; fertig
Alles anzeigen
Dafür hat mein Code den Nachteil, nicht 256 zu erreichen. Ist aber zu verkraften, finde ich.
Bleiben die drei $10 am Fileanfang: Die bedeuten was, denn wenn ich sie ändere, wird das Bild nicht mehr ordentlich dargestellt. Außerdem scheint das gepackte Bild seine Hintergrundfarbe irgendwo anders herzubeziehen als das ungepackte, denn im obigen Fall kriege ich immer Weiß (ich setze aber generell Schwarz...)
Arndt