BASICload -- MC loader für BASIC

Zirias/Excess · Jan 15th 2019

So, dann möchte ich hier auch mal etwas vorstellen, was für meinen Beitrag zu "BASIC-Weihnachten" entstanden ist. Ich hatte ja früh die Idee, "nette" Musik einzubinden und dazu einen möglichst minimalen SID-Player für BASIC zu schreiben (der wird später auch noch separat veröffentlicht). Problem war dann, obwohl der nicht allzu viel kann, war der Code doch für ein abzutippendes BASIC-Programm recht groß -- 64 Zeilen DATA-Wüste nur für den Player waren es beim ersten Versuch. Außerdem dauerte da natürlich auch der Start recht lange .. DATA/READ und POKE sind nicht gerade flott.

Also habe ich mir etwas überlegt, um das besser zu machen. Die Idee war schnell, dass in den BASIC Zeilen einfach direkt der MC-Code als hex steht. Leider pfuscht da der Tokenizer rein, die Sequenz "DEF" wird z.B. in ein Token übersetzt. Also mussten noch Anführungszeichen drumherum.

Das Ergebnis ist ein kleines (PC) Tool, das ein PRG mit dem Maschinencode nimmt und passenden BASIC-Source ausgibt, inklusive einer kleinen Laderoutine, die "klassisch" per DATA/POKE in den Datasettenpuffer geschrieben wird. Diese Routine liest dann die Hex-Strings und springt am Ende direkt zu dem geladenen Maschinencode (es wird erwartet, dass die Ladeadresse auch die Einsprungadresse ist).

Im Ergebnis wird das BASIC Programm ein gutes Stück kleiner als mit klassischem DATA/POKE und die Geschwindigkeit ist um ein Vielfaches besser. Falls man viele sich wiederholende Bytes hat wird das Abtippen schwieriger (Nullen zählen) -- das kann man dann aber elegant durch crunchen (z.B. mit exomizer) umgehen.

Source: https://github.com/Zirias/c64_basicload
Da ist auch ein kleines README -- Aufruf z.B. mit basicload <mycode.prg >loader.bas.

Einen win32 build hänge ich mal an

Hier noch der kommentierte Source der Laderoutine:

Code

.code
.word $0334 ; load address (datasette buffer)
ldx #$1 ; index for writing start address
stx $2 ; init marker for hi-/lo- nibble
lineloop: jsr $0073 ; get next character from BASIC
beq eol ; 0 -> end of BASIC line
hexloop: jsr $0073 ; next char
beq done ; 0 -> end of BASIC program
cmp #'"'
beq checkend ; another quote, check whether done
sbc #$30 ; subtract offset for '0'
cmp #$11
bcc digit ; if below 10, it was a decimal digit
sbc #$7 ; otherwise subtract diff '10' to 'A'
digit: lsr $2 ; check bit #0 of marker
bcc seconddigit ; not set -> second digit (lo nibble)
asl ; otherwise shift 4 bits
asl
asl
asl
sta $fb ; store to temporary
bcc hexloop ; and continue at next digit
seconddigit: ora $fb ; combine with hi nibble
sec
rol $2 ; shift a 1 back into bit #0
cpx #$3 ; start address already read?
bne setpointers ; if not, set pointers
write: sta $0101 ; store to dest (placeholder)
inc write+1 ; next address
bne hexloop ; and repeat
inc write+2 ; on overflow, also increment hi byte
bne hexloop
setpointers: sta done,x ; write pointer to start program
sta write,x ; write pointer to store program
inx ; next index
bne hexloop ; and repeat
checkend: jsr $0073 ; on '"', get next character
beq eol ; 0 -> end of BASIC line
done: jmp $af08 ; start our program (placeholder)
eol: ldy #$5 ; load first character of next
lda ($7a),y ; BASIC line
cmp #'"'
bne done ; if it's not '"', we're done loading
ldy #$2 ; check next BASIC line pointer
lda ($7a),y
beq done ; 0 -> end of BASIC program, so done
iny
lda ($7a),y ; copy next BASIC line number
sta $39 ; to ZP location where BASIC expects it
iny
lda ($7a),y
sta $3a
clc
tya
adc $7a ; move CHRGET pointer to start of
sta $7a ; next BASIC line
bcc lineloop ; and continue reading
inc $7b ; adjust hi-byte on carry
bne lineloop

Display More

Zirias/Excess · Jan 16th 2019

Örks! Ich habe aus Versehen einen Build von einem alten (nicht veröffentlichten) Stand hochgeladen, der noch keinen Parameter für die Startzeilennummer kann. Kann das leider nicht mehr löschen/editieren

Der Anhang im Eingangspost ist Müll!

Hier im Anhang kommt der Build, der auch wirklich zu der Version auf Github passt Jetzt auch "gestrippt" (also ohne Debugging-Symbole).

Übrigens, der C-Code ist, mehr oder weniger bewusst, "gemurkst". Es ging darum, möglichst schnell ein funktionierendes Tool für meinen Beitrag zum Heftchen zu haben. Nichtsdestotrotz funktioniert's natürlich Über den ASM Code des Loaders habe ich allerdings etwas länger nachgedacht, der sollte ja so kurz wie nur möglich werden. Wenn jemand noch eine Möglichkeit findet weiter zu kürzen, bitte posten

Haubitze · Jan 16th 2019

ich wuerde evtl versuchen bei hexloop eine tabelle zu benutzen, das koennte ein paar bytes rausholen.
leider hab ich noch nicht richtig verstanden was das prg machen soll.

es laed eine "string" prg nach und springt dann in dieses?

ich stelle mir das so vor

Code

;$02 holds the loaded petscii charakter
;X is the output value
ldy #$01;hi or low flag?
ldx #$0f
hexloop:
...
loop:
lda petscii,x
cmp $02
beq found
dex
bne loop
found: ;convert and store it as byte
txa
cpy #$0
beq lo
asl
asl
asl
asl
lo:
ora $fb
sta $fb
dey
bpl hexloop; lo value read? no then next run
;....
petscii:
!text "0123456789abcdef"; this is not a byte array or screencode it is petscii text

Display More

ob das funktioniert hab ich jetzt nich getestet und wie die geschwindigkeit ist, ist auch fraglich.
auch ob das kuerzer wird hab ich jetzt nicht nachgezaehlt.
evtl kannst ja was draus machen.

salute

Zirias/Excess · Jan 16th 2019

Quote from Haubitze

leider hab ich noch nicht richtig verstanden was das prg machen soll.

Also, am einfachsten sieht man das wohl an einem Beispiel: Wenn ich es auf meine Uhr (in der Version mit Systemzeichensatz) "loslasse" kommt folgendes "BASIC" heraus:

Code

0 fora=820to932:readb:pokea,b:next:data162,1,134,2,32,115,0,240,68,32,115,0,240
1 data60,201,34,240,51,233,48,201,17,144,2,233,7,70,2,144,8,10,10,10,10,133,251
2 data144,227,5,251,56,38,2,224,3,208,13,141,1,1,238,100,3,208,210,238,101,3
3 data208,205,157,126,3,157,99,3,232,208,196,32,115,0,240,3,76,8,175,160,5,177
4 data122,201,34,208,245,160,2,177,122,240,239,200,177,122,133,57,200,177,122
5 data133,58,24,152,101,122,133,122,144,151,230,123,208,147:sys820,"c0c2a97f8d"
6 "0ddcad0ddca9898d1403a9c38d1503a9478d0803a9c48d0903a212bd4ac59d00d0ca10f7a90"
7 "08dffff8d17d08d1dd08d1cd0a2bf8e00c3a240a0039dc0bfe8d0faee00c388d0f4aaa8207a"
8 "c420cdc420e5c3ad21d085fea90a8dfac78dfdc7a9ff8d15d0a9338501a207a015bd80d1990"
9 "0c0bd88d19940c0bd90d19980c0bd98d199c0c0bda0d19900c1bda8d19940c1bdb0d19980c1"
10 "bdb8d199c0c1bdc0d19900c2bdc8d19940c2bdd0d19980c2888888ca10b8a9378501a901a2"
11 "079d27d0ca10fa8d1ad0600e19d0a91b8d11d0a5fe8d21d0ad00dd09038d00dda9fa8d12d0"
12 "a9b88d1403a9c38d150320d8c4900320e5c34c31ea0e19d0a9138d11d0ad21d085fead20d0"
13 "8d21d0ad00dd29fc8d00dda9898d1403a9c38d1503a9328d12d04c81ea86fb84fc201bc4ad"
14 "5dc58dfec7ad5ec58dffc7a5fb201bc4ad5dc58dfbc7ad5ec58dfcc7a5fc201bc4ad5dc58d"
15 "f8c7ad5ec58df9c7608502a9008d5dc58d5ec5a008ad5ec5c905300569028d5ec50602ad5e"
16 "c52ac910290f8d5ec52e5dc588d0e16020730008c940f004284ce7a728207300c954f0034c"
17 "08af20b2b1a5658d73c4209bb78e71c4209bb78aa2ffa0ff20c0c44caea78d5fc58e60c58c"
18 "61c5a97f8d0ddd8d66c5a9008d65c58d07dd8d0edd8d0fddada602f008a989a2f0a00fd006"
19 "a9dea280a01e8d04dd8e05dd8c06dda9118d0edda9518d0fdd608d62c58e63c58c64c5ee65"
20 "c560ad5fc5ae60c5ac61c53860ad65c5f021ad62c58d5fc5ad63c58d60c5ad64c58d61c5a9"
21 "008d65c5a9808d66c520b5c4d0cfad06ddcd66c58d66c5f03f903dada602d006ce0eddee0e"
22 "ddae5fc5e88e5fc5e03c90aca2008e5fc5ae60c5e88e60c5e03c909ca2008e60c5ae61c5e8"
23 "8e61c5e018908ca2008e61c5f085186018fb20fb28fb30fb38fb40fb48fb50fbff1b32"

Display More

Zum Vergleich der "klassische" Ansatz, der das gesamte Maschinenprogramm aus DATA-Zeilen lädt:

Code

0 fora=49856to50524:readb:pokea,b:next:sys49856:data169,127,141,13,220,173,13
1 data220,169,137,141,20,3,169,195,141,21,3,169,71,141,8,3,169,196,141,9,3,162
2 data18,189,74,197,157,0,208,202,16,247,169,0,141,255,255,141,23,208,141,29
3 data208,141,28,208,162,191,142,0,195,162,64,160,3,157,192,191,232,208,250,238
4 data0,195,136,208,244,170,168,32,122,196,32,205,196,32,229,195,173,33,208,133
5 data254,169,10,141,250,199,141,253,199,169,255,141,21,208,169,51,133,1,162,7
6 data160,21,189,128,209,153,0,192,189,136,209,153,64,192,189,144,209,153,128
7 data192,189,152,209,153,192,192,189,160,209,153,0,193,189,168,209,153,64,193
8 data189,176,209,153,128,193,189,184,209,153,192,193,189,192,209,153,0,194,189
9 data200,209,153,64,194,189,208,209,153,128,194,136,136,136,202,16,184,169,55
10 data133,1,169,1,162,7,157,39,208,202,16,250,141,26,208,96,14,25,208,169,27
11 data141,17,208,165,254,141,33,208,173,0,221,9,3,141,0,221,169,250,141,18,208
12 data169,184,141,20,3,169,195,141,21,3,32,216,196,144,3,32,229,195,76,49,234
13 data14,25,208,169,19,141,17,208,173,33,208,133,254,173,32,208,141,33,208,173
14 data0,221,41,252,141,0,221,169,137,141,20,3,169,195,141,21,3,169,50,141,18
15 data208,76,129,234,134,251,132,252,32,27,196,173,93,197,141,254,199,173,94
16 data197,141,255,199,165,251,32,27,196,173,93,197,141,251,199,173,94,197,141
17 data252,199,165,252,32,27,196,173,93,197,141,248,199,173,94,197,141,249,199
18 data96,133,2,169,0,141,93,197,141,94,197,160,8,173,94,197,201,5,48,5,105,2
19 data141,94,197,6,2,173,94,197,42,201,16,41,15,141,94,197,46,93,197,136,208
20 data225,96,32,115,0,8,201,64,240,4,40,76,231,167,40,32,115,0,201,84,240,3,76
21 data8,175,32,178,177,165,101,141,115,196,32,155,183,142,113,196,32,155,183
22 data138,162,255,160,255,32,192,196,76,174,167,141,95,197,142,96,197,140,97
23 data197,169,127,141,13,221,141,102,197,169,0,141,101,197,141,7,221,141,14
24 data221,141,15,221,173,166,2,240,8,169,137,162,240,160,15,208,6,169,222,162
25 data128,160,30,141,4,221,142,5,221,140,6,221,169,17,141,14,221,169,81,141,15
26 data221,96,141,98,197,142,99,197,140,100,197,238,101,197,96,173,95,197,174
27 data96,197,172,97,197,56,96,173,101,197,240,33,173,98,197,141,95,197,173,99
28 data197,141,96,197,173,100,197,141,97,197,169,0,141,101,197,169,128,141,102
29 data197,32,181,196,208,207,173,6,221,205,102,197,141,102,197,240,63,144,61
30 data173,166,2,208,6,206,14,221,238,14,221,174,95,197,232,142,95,197,224,60
31 data144,172,162,0,142,95,197,174,96,197,232,142,96,197,224,60,144,156,162,0
32 data142,96,197,174,97,197,232,142,97,197,224,24,144,140,162,0,142,97,197,240
33 data133,24,96,24,251,32,251,40,251,48,251,56,251,64,251,72,251,80,251,255,27
34 data50

Display More

Die Version mit meinem Tool ist hier gute 10 Zeilen kürzer und in einem Bruchteil der Zeit geladen und gestartet

Deine Idee mit Tabelle kann ich mir mal anschauen, denke aber das verkürzt den Code weniger als der zusätzliche Platz, den die Tabelle braucht?

Haubitze · Jan 16th 2019

ah alles klar jetzt leuchtet mir das ein.
ja denke auch das die version mit der tabelle nicht die schlauste ist, sah ich aber auch erst jetzt beim nachzaehlen der
bytes in deiner routine.

was mir aber auffaellt ist der check auf alpha numeric und nummeric
evtl ist das hier ja nicht kuerzer

gut das prueft halt nich auf richtigkeit der eingabe ne

Code

HEXDIG CMP #'a' (alphabetic digit?)
BCC SKIP (no, skip next part)
SBC #6 (sub seven)
SKIP SBC #'0' (convert to value)

Zirias/Excess · Jan 16th 2019

Quote from Haubitze

gut das prueft halt nich auf richtigkeit der eingabe ne

Das tut mein originaler Code auch nicht. Wozu auch, soll ja etwas parsen, was vom Tool generiert ist, und wenn es um abtippen geht, wie für das BASIC Magazin hier, hat man hoffentlich einen Checksummer

Ziel war wirklich nur so klein und schnell wie möglich

Quote from Haubitze

evtl ist das hier ja nicht kuerzer

Hm, wenn ich jetzt nichts übersehe ist das genau gleich lang wie meine Variante:

Code

sbc #$30
cmp #$11
bcc digit
sbc #$7
digit: [...]

Mac Bacon · Jan 16th 2019

Wenn der Source explizit zum Abtippen vorgesehen ist, wäre noch ein Prüfsummenalgorithmus wichtig.
Ich hab mal ein ähnliches Programm geschrieben (aber nie veröffentlicht), mit dem ich z.B. dies und dies erzeugt habe. Als "Kodierung" sind dabei sowohl Dezimalbytes als auch Strings möglich, da bei sehr kurzen zu bearbeitenden Programmen das längere Dekoderprogramm schwerer wiegt als die höhere Nutzdatendichte der Strings.

Das Dekoderprogramm ist zwar nur Basic und damit langsam, aber da das Ergebnis in eine neue Datei geschrieben wird, finde ich das nicht schlimm: Das abgetippte Programm lässt man so eh nur ein einziges Mal laufen.

Zirias/Excess · Jan 16th 2019

@Mac Bacon -- das ist ein etwas anderer Anwendungsfall Hier ging es ja grundsätzlich um BASIC-Programme, ich wollte aber Maschinencode mit einbinden. Das wird "klassisch" mit DATA/POKE gelöst, in der Regel auch ohne zusätzliche Prüfung. Das hier optimiert Platzbedarf und Geschwindigkeit. Für die Sicherheit beim Abtippen sollte IMHO lieber ein separater Checksummer sorgen, damit das abzutippende Programm nicht unnötig aufgebläht wird. (man tippt ja nur einmal ab, führt aber eventuell viele male aus ...)

Quote from Mac Bacon

[...] da bei sehr kurzen zu bearbeitenden Programmen das längere Dekoderprogramm schwerer wiegt als die höhere Nutzdatendichte der Strings.

Das hier ist ja genau für ein "etwas größeres" MC-Fragment entstanden, wo das eben nicht so ist. Bei kleineren Routinen lohnt sich das selbstverständlich nicht, auch nicht für die Ladegeschwindigkeit.

(edit, OT -- verdammt lustiger Thread mit dem abtippbaren disk image ... )

Haubitze · Jan 16th 2019

hm ist das evtl 2 bytes kuerzer und erfuellt die selbe function?

Code

digit:
lsr $2 ; check bit #0 of marker
bcc seconddigit ; not set -> second digit (lo nibble)
asl ; otherwise shift 4 bits
asl
asl
asl
seconddigit:
ora $fb
sta $fb ; store to temporary
bcc hexloop ; and continue at next digit
sec
rol $2 ; shift a 1 back into bit #0
cpx #$3 ; start address already read?
bne setpointers ; if not, set pointers

Display More

hab halt schon lange nix mehr am cevi gemacht, von daher is mein verstaendniss deiner routinen gerade nicht das beste ;D

Zirias/Excess · Jan 16th 2019

Das ist doch gleich lang? würde aber auch nicht funktionieren, weil so $fb ja nie gelöscht würde -- der gelesene wert würde also zu einem fixen #$ff "konvergieren"

Wenn noch mehr Leute so eifrig Kürzungsmöglichkeiten suchen könnte man glatt einen Wettbewerb draus machen

Bagitman · Jan 16th 2019

Vielleicht bin das ja nur ich, aber ich komme mit diesen langen Brocken von Zeilen wie in Beitrag 4 weniger klar als mit den typischen DATA-Zeilen mit den Ziffern mit Kommata getrennt. Da kann man so leicht den Überblick verlieren wenn man nicht 101%ig hochkonzentriert dabei ist. Da tippe ich lieber mehr Zeilen altmodisch ab.

Haubitze · Jan 16th 2019

hm okay war ja nur hn versuch ;D
ansonsten finde ich nichts wo ich kuerzen koennte, evtl guggn ja die richtigen profis hier ma rein und finden was

Zirias/Excess · Jan 17th 2019

@Bagitman ich habe es natürlich selbst getestet -- konnte bei mir keine Schwierigkeiten finden. Anders wäre es sicher bei "repetitivem" code, aber der verwirrt auch (wenn auch weniger) in DATA zeilen und das lässt sich wie gesagt durch crunchen umgehen.

Kann schon gut sein, dass das individuell verschieden ist. Aber die Größenunterschiede allein sind schon sehr deutlich -- in DATA zeilen braucht ein Byte des Codes, bei Annahme einer Normalverteilung, im Schnitt 3,6 Zeichen -- gegenüber genau 2 Zeichen mit diesen Hex Strings. Wenn es um Startgeschwindigkeit geht reden wir sogar von Größenordnungen -- gemessen habe ich allerdings noch nicht

Zirias/Excess · Jan 17th 2019

So, habe jetzt mal beide Varianten für die Uhr gemessen mit

Code

100 print ti
ti$="000000":run

Ergebnis ist

Komplett aus DATA: 288 jiffies
Mit meinem Loader: 56 jiffies

Verhältnis ist hier also ca 5:1. Und die Uhr ist ja noch ein relativ kleines Progrämmchen, da hat das laden des Loaders selbst noch einen spürbaren Anteil