Anpassung alter Loader ans Easyflash u.a.

Stephan Scheuer · 30. April 2019

Es wird schon etwas ausführlicher.

1. Vorstellung des anzupassenden Spiel. Z.B. "Summer Games"
2. Änderungen, die am Spielecode erforderlich sind.
3. Vorstellung und Erläuterung der EasyFlash Leseroutine mit dokumentierten Quellcode. Diese Routine ist so kurz gehalten, wie möglich. Zudem kann diese universal eingesetzt werden.
4. Assemblierung und Einbau der Routine in dem Spiel.
5. Das Linken der Game-Dateien mit dem "EasyFlash-crt Maker"
6. Dass Hinzufügen der Autostartdatei und der EAPI mit dem NdefGui-Tool.
7. Erklärung, wie man selber eine Autostartdatei erstellt. Entweder über $FFFC/$FFFD oder mittels CBM80.
8. Vielleicht auch noch eine Erklärung, wie ein Easyflash Wrapper Programm funktioniert (Disk2EasyFlash) z.B.

Gruß: Stephan

Ich wünsche allen hier im Forum einen schönen 1. Mai

mrr19121970 · 30. April 2019

Es ist hier erlärt:

http://codebase64.org/doku.php?id=base:code_sample&s[]=easyflash

Code

; EasyFlashSDK sample code
; see README for a description details
* = 00
EASYFLASH_BANK = $DE00
EASYFLASH_CONTROL = $DE02
EASYFLASH_LED = $80
EASYFLASH_16K = 7
EASYFLASH_KILL = 4
; =============================================================================
; 00:0:0000 (LOROM, bank 0)
bankStart_00_0:
; This code resides on LOROM, it becomes visible at $8000
!pseudopc $8000 {
; === the main application entry point ===
; copy the main code to $C000 (or whereever) - we don't run it here
; since the banking would make it invisible
; it may be a good idea to let exomizer do this in real life
ldx #0
lp1:
lda main,x
sta $c000,x
dex
bne lp1
jmp $c000
main:
!pseudopc $C000 {
; Switch to bank 1, get a byte from LOROM and HIROM
lda #1
sta EASYFLASH_BANK
lda $8000
ldx $a000
; and put them to the screen, we should see "A" and "B" there
sta 400
stx 401
; Switch to bank 2, get a byte from LOROM and HIROM
lda #2
sta EASYFLASH_BANK
lda $8000
ldx $a000
; and put them to the screen, we should see "C" and "D" there
sta 400 + 40
stx 401 + 40
; effect!
lp2:
dec $d020
jmp lp2
}
; fill the whole bank with value $ff
!align $ffff, $a000, $ff
}
; =============================================================================
; 00:1:0000 (HIROM, bank 0)
bankStart_00_1:
; This code runs in Ultimax mode after reset, so this memory becomes
; visible at $E000..$FFFF first and must contain a reset vector
!pseudopc $e000 {
coldStart:
; === the reset vector points here ===
sei
ldx #$ff
txs
cld
; enable VIC (e.g. RAM refresh)
lda #8
sta $d016
; write to RAM to make sure it starts up correctly (=> RAM datasheets)
startWait:
sta 100, x
dex
bne startWait
; copy the final start-up code to RAM (bottom of CPU stack)
ldx #(startUpEnd - startUpCode)
l1:
lda startUpCode, x
sta 100, x
dex
bpl l1
jmp 100
startUpCode:
!pseudopc 100 {
; === this code is copied to the stack area, does some inits ===
; === scans the keyboard and kills the cartridge or ===
; === starts the main application ===
lda #EASYFLASH_16K + EASYFLASH_LED
sta EASYFLASH_CONTROL
; Check if one of the magic kill keys is pressed
; This should be done in the same way on any EasyFlash cartridge!
; Prepare the CIA to scan the keyboard
lda #$7f
sta $dc00 ; pull down row 7 (DPA)
ldx #$ff
stx $dc02 ; DDRA $ff = output (X is still $ff from copy loop)
inx
stx $dc03 ; DDRB = input
; Read the keys pressed on this row
lda $dc01 ; read coloumns (DPB)
; Restore CIA registers to the state after (hard) reset
stx $dc02 ; DDRA input again
stx $dc00 ; Now row pulled down
; Check if one of the magic kill keys was pressed
and #$e0 ; only leave "Run/Stop", "Q" and "C="
cmp #$e0
bne kill ; branch if one of these keys is pressed
; same init stuff the kernel calls after reset
ldx #0
stx $d016
jsr $ff84 ; Initialise I/O
; These may not be needed - depending on what you'll do
jsr $ff87 ; Initialise System Constants
jsr $ff8a ; Restore Kernal Vectors
jsr $ff81 ; Initialize screen editor
; start the application code
jmp $8000
kill:
lda #EASYFLASH_KILL
sta EASYFLASH_CONTROL
jmp ($fffc) ; reset
}
startUpEnd:
; fill it up to $FFFA to put the vectors there
!align $ffff, $fffa, $ff
!word reti ; NMI
!word coldStart ; RESET
; we don't need the IRQ vector and can put RTI here to save space :)
reti:
rti
!byte 0xff
}

Alles anzeigen

Stephan Scheuer · 30. April 2019

Oh, thanks for the link. The website is known to me but I did not know the thread yet.

By the way. Another webside. There are also massive instructions. Best suited for beginners. German only.

https://www.retro-programming.de/

Achja, was mir an diversen Quellcodes nicht gefällt, ist das gemixe von hexadezimalwerten, dezimalzahlen und binärkolonnen. Ich weiß, dass man das so macht, aber mich stört es.

mrr19121970 · 30. April 2019

This is the method I use.

I don't use these tools:

Zitat von Stephan Scheuer

5. Das Linken der Game-Dateien mit dem "EasyFlash-crt Maker"
6. Dass Hinzufügen der Autostartdatei und der EAPI mit dem NdefGui-Tool.

linking is done by TAS code only.

Stephan Scheuer · 30. April 2019

My EasyFlash file linker is ready too. This works in conjunction with the SCPU. I've used it to create my REU, Georam, and SCPU customizations.
I use the "EasyFlash-crt Maker" to explain, so it will not be too much for the readership.

Vectorhead · 30. April 2019

Zitat von Stephan Scheuer

Es wird schon etwas ausführlicher.
.......

Yes, ich bin gespannt wie ein Pfüzipfeil.
Danke im Voraus.

Stephan Scheuer · 30. April 2019

Hier mal mein Linker

Code

; ---- für das erstellen und anppassen von spiele an die georam, reu und scpu+ramcard
; ---- auf der disk bitte nur die dateien, die später aus dem scpu-ram geladen werden, belassen
; ---- voreingestellt für die 1581
; ---- liest das directory in das ram des c64
; ---- linkt alle dateien auf der disk zusammen und erstellt ein big file
; ---- erstelle tabellen der dateilänge, dateinamen, dateinameslänge,
; ---- dateiadressen im scpu-ram und dateiladeadresse im c64-ram
; ---- zp felder
;
ffa = $fa
;
; ---- zp absolute adressen
;
a01 = $01
ab9 = $b9
aba = $ba
afa = $fa
afb = $fb
afc = $fc
afd = $fd
afe = $fe
aff = $ff
;
; ---- zp pointer
;
pbr03 = $fa ; ---- zeiger des directory einlesepuffer (im moment $4000)
;
; ---- absolute adressen
;
abr01 = pbr03
abr02 = pbr03 + 1
;
; ---- pointer
;
tab00 = $1000 ; ---- 16bit puffer für die bytelänge einer datei
tab01 = $2000 ; ---- tabelle für die bytelänge der dateien. 16bit low,high
tab02 = $3000 ; ---- tabelle für die scpu-ram adressen der dateien. 24bit low,high,bank
pbr00 = $4000 ; ---- ab hier steht das directory nach dem einlesen. 16bit low,high
tab03 = $9000 ; ---- tabelle für die ladeadressen der dateien. 16bit low,high
pbr02 = $a000 ; ---- tabelle für die namenslänge der dateien. 8bit low
pbr01 = $b000 ; ---- tabelle für die namen der dateien. 01-16 zeichen
; ------------------------------------------------------------------------------
; ---- aufbau des scpu directory. der daten-offset beginnt immer ab $030000 ----
; ------------------------------------------------------------------------------
;
; -------------------------------------------------------------------------
; ---- dateiname #$10 byte - der dateiname und das kontrollbyte ----
; ---- bytelänge #$02 byte - länge der zu ladenden datei in bytes ----
; ---- ladeadresse #$02 byte - die ladeadresse der datei im c64-ram ----
; ---- scpu-low #$01 byte - low-byte offset-adresse im scpu-ram ----
; ---- scpu-high #$01 byte - high-byte offset-adresse im scpu-ram ----
; ---- scpu-bank+3 #$01 byte - bank-byte offset-adresse im scpu-ram ----
; -------------------------------------------------------------------------
; ------------------------------------------------------------------------------------
; ---- aufbau des georam directory. der daten-offset beginnt immer ab page $00, bank $00 ----
; ------------------------------------------------------------------------------------
;
; ------------------------------------------------------------------
; ---- dateiname #$10 byte - dateiname und das kontrollbyte ----
; ---- bytelänge #$02 byte - die länge der datei in bytes ----
; ---- ladeadresse #$02 byte - ladeadresse der datei im c64ram ----
; ---- page offset #$01 byte - die adresse in der 256byte page ----
; ---- georam page #$01 byte - eine von #$3f pages einer bank ----
; ---- georam bank #$01 byte - eine 512kb georam hat #1f bänke ----
; ------------------------------------------------------------------
;
; -----------------------------------------------------------
; ---- das kontrollbyte ist für zukünftige erweiterungen ----
; -----------------------------------------------------------
drivenr = $08 ; ---- ziellaufwerk
; ---- #$31,#38,#$30,#$01 ; ---- track- und sektorwerte für die 1541
!to "scpu tab-maker.prg",cbm
!cpu 65816
*= $00c000
; ---- weitere arbeiten
;
; ---- dem scpu-direktory nach "georam-directory" konverter einbauen
; ---- dem scpu-direktory nach "easyflash-directory" konverter einbauen
; ---- den scpu-directory nach "reu-directory" konverter einbauen
; ---- die bildschirmanzeigen fertig machen.
; ---- eventuel eine laufwerksadressauswahl einbauen. adressen 08,09,10
; ---- eventuell eine laufwerksauswahl einbauen. 1541,1581,fd-2000 ect
; ---- den code soweit wie möglich auf 16bit ändern.
; ---- für jede tabelle eine eigene bank reservieren
; ---- alles nötige auf 24bit adressierung umstellen
; ---- den code soweit wie möglich optimieren
lda #$36 ; ---- wert in den akku laden
sta $01 ; ---- basic-rom ausblenden
clc ; ---- carry-flag löschen
xce ; ---- exchange carry und emulation flags
rep #$30 ; ---- 16-bit accumulator and index register
!al ; ---- akku 16bit
!rl ; ---- register 16bit
ldx #$0000 ; ---- x-register auf #0000 festlegen
lda #$0000 ; ---- akku auf #0000 festlegen
loe05 sta $0900,x ; ---- ram mit den wert #0000 ab startadresse $0900 löschen
inx ; ---- x-register um einen erhöhen
inx ; ---- x-register um einen erhöhen
cpx #$b500 ; ---- x-register mit endadresse vergleichen
bne loe05 ; ---- wenn endadresse erreicht wurde, dann
sep #$30 ; ---- 8-bit accumulator and index register
sec ; ---- carry-flag setzen
xce ; ---- exchange carry und emulation flags
!rs ; ---- register 8bit
lda #$20 ; ---- wert in den akku laden
ldx #$00 ; ---- x-register startwert festlegen
itu66 sta $0400,x ; ---- bildschirm löschen
sta $0500,x ; ---- bildschirm löschen
sta $0600,x ; ---- bildschirm löschen
sta $0700,x ; ---- bildschirm löschen
inx ; ---- x-register um einen erhöhen
bne itu66 ; ---- wenn der bildschirm gelöscht wurde, dann
; -------------------------------------------------------------------
; ---- zählerstartwert der geladenen dateien auf "000" festlegen ----
; -------------------------------------------------------------------
lda #$30 ; ---- ascii wert "0" in den akku laden
sta $057d ; ---- und als erste ziffer des dateizähler festlegen
sta $057e ; ---- und als zweite ziffer des dateizähler festlegen
sta $057f ; ---- und als dritte ziffer des dateizähler festlegen
lda #$0e ; ---- farbe für hellblau in den akku laden
sta $d97d ; ---- und für die erste ziffer in das farbram schreiben
sta $d97e ; ---- und für die zweite ziffer in das farbram schreiben
sta $d97f ; ---- und für die dritte ziffer in das farbram schreiben
lda #$00 ; ---- wert für dunkelgrau in den akku laden
sta $d020 ; ---- und als rahmenfarbe festlegen
sta $d021 ; ---- und als bildschirmfarbe festlegen
ldx #$0e ; ---- anzahl der auszugebenen zeichen in das x-register laden
syd04 lda trn0e,x ; ---- und den text "number of files"
sta $056a,x ; ---- auf dem bildschirm ausgeben
lda #$04 ; ---- akku mit farbwert lila laden
sta $d96a,x ; ---- und in das farbram schreiben
dex ; ---- x-register um einen vermindern
bpl syd04 ; ---- wenn alles ausgegeben wurde, dann
ldx #$0c ; ---- anzahl der auszugebenen zeichen in das x-register laden
txt01 lda trn0c,x ; ---- text "loading files" auf
sta $051a,x ; ---- auf bildschirm ausgeben
lda #$02 ; ---- wert für farbe rot
sta $d91a,x ; ---- textfarbe im farbram festlegen
lda #$09 ; ---- wert für farbe lila
sta $d889,x ; ---- textfarbe im farbram festlegen
dex ; ---- x-register um einen vermindern
bpl txt01 ; ---- wenn alles ausgegeben wurde, dann
lda #$34 ; ---- start track #40 high-byte in den akku laden
sta set01+08 ; ---- und festlegen
lda #$30 ; ---- start track #40 low-byte in den akku laden
sta set01+09 ; ---- und festlegen
lda #$30 ; ---- start sektor #00 high-byte in den akku laden
sta set01+11 ; ---- und festlegen
lda #$33 ; ---- start sektor #03 low-byte in den akku laden
sta set01+12 ; ---- und festlegen
lda #<pbr00 ; ---- ram-startadresse des eingelesenen directory low-byte in den akku laden
sta abr01 ; ---- und festlegen
lda #>pbr00 ; ---- ram-startadresse des eingelesenen directory high-byte in den akku laden
sta abr02 ; ---- und festlegen
str01 jsr brs01 ; ---- einen directory-sektor einlesen
ldy #$00 ; ---- y-register auf #01 festlegen
lda (pbr03),y ; ---- directory trackverkettungs byte in den akku laden
tax ; ---- akku in das x-register schieben
cpx #$00 ; ---- letzten direcktory track eingelesen?
beq ast24 ; ---- wenn #$00 dann sind alle dir-sektoren eingelesen worden
lda #<set01+8 ; ---- offset für hex to ascii
sta gtr01+1 ; ---- und in hex to ascii konverter schreiben
jsr gns01 ; ---- tracklink von hex nach ascii für den "u1 2 0" floppy command-code wandeln
ldy #$01 ; ---- y-register auf #01 festlegen
lda (pbr03),y ; ---- directory sektorverkettungs byte in den akku laden
tax ; ---- akku in das x-register schieben
lda #<set01+$0b ; ---- offset für hex to ascii
sta gtr01+1 ; ---- und in hex to ascii konverter schreiben
jsr gns01 ; ---- sektorlink von hex nach ascii für den "u1 2 0" floppy command-code wandeln
inc abr02 ; ---- directory-puffer high-byte um einen erhöhen
jmp str01 ; ---- nächsten direktory-sektor einlesen
ast24 inc abr02 ; ---- directory-puffer high-byte um einen erhöhen
lda abr02 ; ---- directory-puffer high-byte in den akku laden
sta end01+1 ; ---- und als endmarker festlegen
jsr drs01 ; ---- dateinamen in tabelle einordnen
lda cab01+1 ; ---- low-byte der tabelle für die dateinamenslänge in den akku laden
sta tal01+2 ; ---- und in die tabelle der save-routine eintragen
lda cab01+2 ; ---- high-byte der tabelle für die dateinamenslänge in den akku laden
sta tal01+3 ; ---- und in die tabelle der save-routine eintragen
jsr kcr01 ; ---- alle dateien laden und tabellen erstellen
lda #$02 ; ---- wert für die farbe rot in den akku laden
sta $d020 ; ---- und festlegen
ldx #$18 ; ---- anzahl der auszugebenen zeichen in das x-register laden
txt03 lda trn18,x ; ---- text "turn disk" auf
sta $0598,x ; ---- auf bildschirm ausgeben
lda #$05 ; ---- wert für farbe grün in den akku laden
sta $d998,x ; ---- und als textfarbe festlegen
dex ; ---- x-register um einen vermindern
bpl txt03 ; ---- wenn alles ausgegeben wurde, dann
ldx #$25 ; ---- anzahl der auszugebenen zeichen in das x-register laden
txt02 lda trn25,x ; ---- text "to save the datas"
sta $05e1,x ; ---- auf bildschirm ausgeben
lda #$06 ; ---- wert für farbe blau in dan akku laden
sta $d9e1,x ; ---- und als textfarbe festlegen
dex ; ---- x-register um einen vermindern
bpl txt02 ; ---- wenn alles ausgegeben wurde, dann
trn01 lda $dc01 ; ---- lade wert von adresse $dc01 in den akku
cmp #$ef ; ---- mit wert wert für die gedrückte leertaste vergleichen
bne trn01 ; ---- wenn leerteste gedrückt wurde, dann
jsr sax01 ; ---- alles abspeichern
jsr sbx01 ; ---- internes directory erstelle und abspeichern
lda #$37 ; ---- wert in den akku laden
sta $01 ; ---- basicrom einblenden
rts ; ---- programm beenden
; -----------------------------------------------------------
; ---- internes scpu-directory erstellen und abspeichern ----
; -----------------------------------------------------------
sbx01 lda fle01 ; ---- anzahl der dateien low-byte
sta ppp01 ; ---- als down-countwert festlegen
lda fle01+1 ; ---- anzahl der dateien high-byte
sta ppp01+1 ; ---- als down-countwert festlegen
lda #$36 ; ---- wert in den akku laden
sta $01 ; ---- und basic-rom ausblenden
lda #$00 ; ---- low-byte offset adresse in den akku laden
sta $fc ; ---- und dateinamen tabelle low-byte festlegen
lda #$b0 ; ---- high-byte offset adresse in den akku laden
sta $fd ; ---- und dateinamen tabelle high-byte festlegen
lda #$00 ; ---- low-byte offset adresse in den akku laden
sta $fe ; ---- und scpu-directory low-byte adresse festlegen
sta bff01 ; ---- und in den additionspuffer schreiben
lda #$40 ; ---- high-byte offset adresse in den akku laden
sta $ff ; ---- scpu-directory high-byte adresse festlegen
sta bff01+1 ; ---- und in den additionspuffer schreiben
; -------------------------------------------------------------------
; ---- scpu-directory ram-bereich ab $4000-$9000 mit #$00 löschen ----
; -------------------------------------------------------------------
ldy #$00
tya
loe01 sta ($fe),y
iny
bne loe01
inc $ff
ldx $ff
cpx #$90
bne loe01
; --------------------------------------------------------
; ---- scpu directory format und dateinamen erstellen ----
; --------------------------------------------------------
lda #$40 ; ---- high-byte offset adresse in den akku laden
sta $ff ; ---- scpu-directory high-byte adresse festlegen
kst06 ldx #$00 ; ---- x-register counterwert auf #$00 festlegen
ldy #$00 ; ---- y-register auf #$00 festlegen
kst01 lda ($fc),y ; ---- wert laden aus dateinamen tabelle start offset $b000
sta ($fe),y ; ---- wert schreiben in scpu-directory start offset $4000
inc $fc ; ---- low-byte dateinamen tabelle $9000 um einen erhöhen
bne kst02 ; ---- wenn das carry-flag gesetzt wurden, dann
inc $fd ; ---- high-byte dateinamen tabelle $9000 um einen erhöhen
kst02 inc $fe ; ---- scpu-directory low-byte um eine erhöhen $4000
bne kst03 ; ---- wenn das carry-flag gesetzt wurden, dann
inc $ff ; ---- scpu-directory high-byte um eine erhöhen $4000
kst03 inx ; ---- x-register um einen erhöhen
kst07 cpx pbr02 ; ---- mit dateinamenslänge aus tabelle vergleichen
bne kst01 ; ---- nächstes zeichen laden, wenn wert in der tabelle kleiner ist
lda #$18 ; ---- wert für nächsten directory-eintrag in den akku laden
clc ; ---- carry-flag löschen
adc bff01 ; ---- den aktuellen puffer-wert hinzu addieren
sta bff01 ; ---- und dann die summe zurückschreiben
bcc kst04 ; ---- wenn das carry-flag gesetzt ist. dann
inc bff01+1 ; ---- high-byte des additions-puffer um einen erhöhen
kst04 lda bff01 ; ---- additions-puffer low-byte in den akku laden
sta $fe ; ---- und als neue low-byte offset-adresse festlegen
lda bff01+1 ; ---- additions-puffer high-byte in den akku laden
sta $ff ; ---- und als neue high-byte offset-adresse festlegen
txa ; ---- aktuelle länge des dateinamens in den akku schieben
clc ; ---- carry-flag löschen
adc bff02 ; ---- und mit dem aktuellen wert im additions-puffer2 low-byte addieren
sta bff02 ; ---- dann die summe in den additionspuffer zurückschreiben
bcc kst08 ; ---- wenn das carry-flag gesetzt ist, dann
inc bff02+1 ; ---- das aktuelle high-byte des additionspuffer2 um einen erhöhen
kst08 lda bff02 ; ---- low-byte aus additionspuffer2 in den akku laden
sta $fc ; ---- und als neue low-byte offset-adresse festlegen
lda bff02+1 ; ---- high-byte aus additionspuffer2 in den akku laden
sta $fd ; ---- und als neue high-byte offset-adresse festlegen
inc kst07+1 ; ---- low-byte offset der tabelle für die namenslänge um einen erhöhen
bne kst05 ; ---- wenn carry-flag gesetzt ist, dann
inc kst07+2 ; ---- high-byte offset der tabelle für die namenslänge um einen erhöhen
kst05 lda ppp01 ; ---- lädt low-byte counter in den akku
bne sst43 ; ---- wenn akku #00 ist, dann
dec ppp01+1 ; ---- high-byte counter für die anzahl der geasmmten dateinamen um einen verringern
sst43 dec ppp01 ; ---- low-byte counter für die anzahl der geasmmten dateinamen um einen verringern
lda ppp01+1 ; ---- lade high-byte counterwert in den akku
bne kst06 ; ---- wenn der akkuwert nicht #00 ist, dann nächsten dateinamen eintragen
lda ppp01 ; ---- lade low-byte counterwert in den akku
bne kst06 ; ---- nenn akku nicht #00 ist, denn nächsten dateinamen eintragen
jsr szr01 ; ---- tabelleneinträge vornehmen
lda #$90 ; ---- high-byte offset für tabelle (ladeadressen) in den akku laden
sta wad01+1 ; ---- und als neue high-byte offset-adresse festlegen
lda #$13 ; ---- scpu-directory low-byte offset in den akku laden
sta wad02+1 ; ---- und als neue low-byte offset-adresse festlegen
jsr szr01 ; ---- tabelleneinträge vornehmen
lda #$30 ; ---- high-byte offset für tabelle (scpu-adressen) in den akku laden
sta wad01+1 ; ---- und als neue high-byte offset-adresse festlegen
lda #$15 ; ---- scpu-directory low-byte offset in den akku laden
sta wad02+1 ; ---- und als neue low-byte offset-adresse festlegen
lda #$03 ; ---- anzahl der einträge pro datei in den akku laden
sta wad03+1 ; ---- und als neuen cpx-vert festlegen
sta wad04+1 ; ---- und als neuen adc-wert festlegen
jsr szr01 ; ---- tabelleneinträge vornehmen
lda #$00 ; ---- low-byte der startadresse des internen directory in den akku laden
sta $fa ; ---- und festlegen
sta $fc ; ---- bank-byte startadresse auf #00 setzen
sta $ff ; ---- bank-byte endadresse auf #00 setzen
lda #$40 ; ---- high-byte der startadresse des internen directory in den akku laden
sta $fb ; ---- und festlegen
lda bff01 ; ---- low-byte der endadresse des internen directory in den akku laden
sta $fd ; ---- und festlegen
lda bff01+1 ; ---- high-byte der endadresse des internen directory in den akku laden
sta $fe ; ---- und festlegen
lda nlo01+1 ; ---- low-byte adresse des directory namen in den akku laden
clc ; ---- carry-flag löschen
adc #$0b ; ---- und adressabstand für den nächsten dateinamen addieren
sta nlo01+1 ; ---- neuen low-byte wert festlegen
bcc oxo99 ; ---- wenn das carry-flag gesetzt wurde, dann
inc hlo01+1 ; ---- high-byte adresse des directory namen um einen erhöhen
oxo99 jsr asr02 ; ---- zur saveroutine
lda #$37 ; ---- wert in den akku laden
sta $01 ; ---- basic- und kernalrom einblenden
rts ; ---- ende der arbeit
; --------------------------------------------------------
; ---- dateiparameter im das scpu-directory eintragen ----
; --------------------------------------------------------
szr01 lda fle01 ; ---- anzahl der dateien low-byte
sta ppp01 ; ---- und als down-countwert festlegen
lda fle01+1 ; ---- anzahl der dateien high-byte
sta ppp01+1 ; ---- und als down-countwert festlegen
lda #$00 ; ---- low-byte offset-wert in den akku laden
sta $fc ; ---- und festlegen. dateigröße tabelle low-byte
wad01 lda #$20 ; ---- high-byte offset-wert in den akku laden
sta $fd ; ---- und festlegen. dateigröße tabelle high-byte
wad02 lda #$11 ; ---- low-byte offset-wert in den akku laden
sta $fe ; ---- und festlegen. scpu-directory low-byte
lda #$40 ; ---- high-byte offset-wert in den akku laden
sta $ff ; ---- und festlegen. scpu-directory high-byte
twt04 ldy #$00 ; ---- y-register auf #$00 setzen
twt01 lda ($fc),y ; ---- lade adressbyte. low- und highbyte
sta ($fe),y ; ---- schreibe adressbyte. low- und highbyte
iny ; ---- y-register um einen erhöhen
wad03 cpy #$02 ; ---- schon zwei adressbytes gelesen
bne twt01 ; ---- wenn nein, zweites byte lesen
lda $fe ; ---- scpu-directory low-byte in den akku laden
clc ; ---- carry-flag löschen
adc #$18 ; ---- und #$18 hinzu addieren
sta $fe ; ---- die summe als nächsten directory eintrag festlegen low-byte
bcc twt02 ; ---- wenn das carry-flag gesetzt ist. dann
inc $ff ; ---- nächsten directory eintrag high-byte um einen erhöhen
twt02 lda $fc ; ---- tabelle für die dateigröße low-byte in den akku laden
clc ; ---- carry-flag löschen
wad04 adc #$02 ; ---- und zwei für den nächsten tabelleneintrag hinzu addieren
sta $fc ; ---- summe als neuen tabellen-offset festlegen. low-byte
bcc twt03 ; ---- wenn das carry-flag gesetzt ist. dann
inc $fd ; ---- tabellen-offset high-byte um einen erhöhen
twt03 lda ppp01 ; ---- low-byte coutdown zähler in den akku laden
bne ern57 ; ---- wenn akku #00 ist, dann
dec ppp01+1 ; ---- high-byte des countdown zähler um einen verringern
ern57 dec ppp01 ; ---- low-byte des countdown zähler um einen verringern
lda ppp01+1 ; ---- high-byte coutdown zähler in den akku laden
bne twt04 ; ---- wenn der akku #00 ist, dann
lda ppp01 ; ---- dann low-byte coutdown zähler in den akku laden
bne twt04 ; ---- wenn der counter auf #$00 ist, dann
rts ; ---- fertig mit dem erstellen
; -------------------------------------------
; ---- einen directory sektoren einlesen ----
; -------------------------------------------
brs01 lda #$01 ; ---- länge des dateiname
ldx #<set01
ldy #>set01
jsr $ffbd ; ---- festlegen des dateinamens
lda #$02 ; ---- logische adresse in den akku laden
ldx $ba
bne ast13
ldx #$08 ; ---- primäradresse in das x-register laden
ast13 ldy #$02 ; ---- sekundäradresse in das y-register laden
jsr $ffba ; ---- setzen der geräteadressen (logische, primär- und sekundäradresse)
jsr $ffc0 ; ---- open: logische datei öffnen
bcs ast11
lda #$0c ; ---- länge das dateiname
ldx #<set01+1 ; ---- übergabe des "u1 2 0" kommando plus track und sektor low-byte
ldy #>set01+1 ; ---- übergabe des "u1 2 0" kommando plus track und sektor high-byte
jsr $ffbd ; ---- festlegen des dateinamens
lda #$0f
ldx $ba
ldy #$0f
jsr $ffba ; ---- setzen der geräteadressen (logische, primär- und sekundäradresse)
jsr $ffc0 ; ---- open: logische datei öffnen
bcs ast11
ldx #$02
jsr $ffc6 ; ---- chkin: eingabe-kanal öffnen
ldy #$00
ast12 jsr $ffcf ; ---- chrin: zeicheneingabe
sta (pbr03),y ; ---- zeiger des puffer für das directory (im moment $4000)
iny
bne ast12
ast11 lda #$0f ; ---- #15 in den akku laden
jsr $ffc3 ; ---- close: logische datei schließen
lda #$02 ; ---- sekundäradresse in den akku laden
jsr $ffc3 ; ---- close: logische datei schließen
jsr $ffcc ; ---- clrchn: ein- und ausgabekanal schließen
rts
; --------------------------------------------------------------
; ---- konvertiert hex to ascii für den nächsten dir-sector ----
; --------------------------------------------------------------
gns01 ldy #$00
stx $be
sty $bf
ldy #$01 ; ---- anzahl der durchläufe
ast21 jsr ast20
ora #$30
gtr01 sta set01,y ; ---- ascii werte in dir-leseroutine eintragen
dey
bpl ast21
rts
ast20 ldx #$11
lda #$00
clc
ast23 rol
cmp #$0a
bcc ast22
sbc #$0a
ast22 rol $be
rol $bf
dex
bne ast23
rts
; ---------------------------------------------
; ---- dateinamen in der tabelle eintragen ----
; ---------------------------------------------
drs01 ldx #<pbr00 ; ---- ram-adresse des eingelesenen directory low-byte
lda #>pbr00 ; ---- ram-adresse des eingelesenen directory high-byte
stx abr01 ; ---- low-byte zeiger des puffer für das directory (pbr03)
sta abr02 ; ---- high-byte zeiger des puffer für das directory (pbr03+1)
bst01 ldy #$02 ; ---- y-register auf #$02 setzen. hier steht der dateityp
lda (pbr03),y ; ---- zeiger des puffer für das directory im ram
cmp #$82 ; ---- wurde eine programmdatei gefunden?
beq bst02 ; ---- wenn ja, dann hier weiter
cmp #$c2 ; ---- wurde eine schreibgeschützte programmdatei gefunden?
beq bst02 ; ---- wenn ja, dann hier weiter
duu02 lda abr01 ; ---- aktuelle directory offset adresse in den akku laden
clc ; ---- carry-flag setzen
adc #$20 ; ---- und #20 für den nächsten eintrag hinzu addieren
sta abr01 ; ---- neue directory offset adresse festlegen
bcc duu01 ; ---- wenn das carry-flag gesetzt wurde, dann
inc abr02 ; ---- das high-byte der directory offset adresse um einen erhöhen
duu01 lda abr02 ; ---- das high-byte der directory offset adresse in den akku laden
end01 cmp #$44 ; ---- wurde das ende des eingelesenen directory erreicht?
bne bst01 ; ---- wenn nicht, nächsten eintrag erfassen
rts ; ---- weiter im programm
; ------------------------------------------------------------
; ---- adresspointer für den nächsten eintrag vorbereiten ----
; ------------------------------------------------------------
bst02 inc fle01 ; ---- low-byte der verarbeiteten dateinamen um einen erhöhen
bne gag01 ; ---- wenn das carry-flag gesetzt wurde dann
inc fle01+1 ; ---- high-byte der verarbeiteten dateinamen um einen erhöhen
gag01 iny ; ---- y-register um einen erhöhen. trackinfo überspringen
iny ; ---- y-register um einen erhöhen. sektorinfo überspringen
bst03 iny ; ---- y-register um einen erhöhen. offset ist der anfang des dateinamen
lda (pbr03),y ; ---- ein zeichen des aktuellen dateinamen in den akku laden
cmp #$a0 ; ---- ende des dateinamen?
beq cab01 ; ---- wenn nein dann den wert das akkus
cab02 sta pbr01,x ; ---- in die tabelle für dateinamen eintragen
inx ; ---- x-register um einen erhöhen
cpx #$10 ; ---- schon 10 zeichen erreicht? wenn nicht, dann
bne bst03 ; ---- nächstes zeichen des dateinamen einlesen
cab01 stx pbr02 ; ---- den wert des x-register in der tabelle für die dateinamenslänge eintragen
inc cab01+1 ; ---- low-byte der tabelle für die dateinamenslänge um einen erhöhen
bne tst01 ; ---- ist das carry-flag gesetzt?
inc cab01+2 ; ---- high-byte der tabelle für die dateinamenslänge um einen erhöhen
tst01 txa ; ---- aktuelle dateinamenslänge in den akku schieben
clc ; ---- carry-flag löschen
adc cab02+1 ; ---- mit aktuelle offset adresse der dateinamentabelle addieren
sta cab02+1 ; ---- summe als nächsten offset für die tabelle der dateinamen festlegen
bcc bst04 ; ---- ist das carry-flag gesetzt?
inc cab02+2 ; ---- wenn ja, dann das offset high-byte der dateinamentabelle um einen erhöhen
bst04 ldx #$00 ; ---- x-register auf #00 setzten
jmp duu02 ; ---- auf directoryende testen und nächsten dateinamen in die tabelle infügen
; ---------------------------------------------------------------------------------------
; ---- das laden einer datei vorbereiten. dateilänge zur offset ladeadresse addieren ----
; ---------------------------------------------------------------------------------------
kcr01 lda #$00 ; ---- low- und highbyte der scpu-ram lade-startadressen in den akku laden
sta tab02 ; ---- scpu-ram lade-startadressen der dateien low-byte in die tabelle eintragen
sta tab02+1 ; ---- scpu-ram lade-startadressen der dateien high-byte in die tabelle eintragen
sta $fd ; ---- ladeadresse low-byte festlegen
sta $fe ; ---- ladeadresse high-byte festlegen
lda #$03 ; ---- adresse für die bank $03 in den akku laden
sta $ff ; ---- ladeadresse bank-byte festlegen
sta tab02+2 ; ---- scpu-ram lade-startadressen der dateien bank-byte in die tabelle eintragen
xwe02 lda #$00 ; ---- startwert in den akku laden
sta tab00 ; ---- 16bit puffer für datei bytelänge low-byte löschen
sta tab00+1 ; ---- 16bit puffer für datei bytelänge high-byte löschen
lda buf80 ; ---- wert vom überlauf puffer in den akku laden
beq xwe01 ; ---- wenn der wert #01 ist, dann
inc nma03+1 ; ---- das high-byte der adressse für die dateinamen um einen erhöhen
dec buf80 ; ---- wert vom überlauf puffer auf #00 setzen
xwe01 ldx #$00 ; ---- x-register startwert #$00. wird als low-byte der namens tabelle genutzt
ywe01 ldy #$00 ; ---- y-register auf #$00 setzen. zähler für die anzahl der geladenen dateien
nml01 lda pbr02,y ; ---- lade wert für die namenslänge der aktuellen datei
sta nam01+1 ; ---- dateinamenslänge festlegen. einzeltabellen
sta nam12+1 ; ---- dateinamenslänge festlegen. scpu-dir
stx nam02+1 ; ---- x-register als ram-adresse des dateinamen low-byte festlegen
clc ; ---- carry-flag löschen
adc nam02+1 ; ---- low-byte ramadresse des dateinamen zum startzeiger hinzuaddieren
sta xwe01+1 ; ---- und auch als nächste ram-adresse für dateiname low-byte festlegen
bcc nma04 ; ---- wurde bei der addition das carry-flag gesetzt? wenn ja, dann
inc buf80 ; ---- überlauf puffer auf #01 setzen
nma04 inc ywe01+1 ; ---- y-register um einen erhöhen für nächste dateinamenslänge
bne dta01 ; ---- wenn carry-flag gesetzt wurde, dann
inc nml01+2 ; ---- high-byte des pointers für die dateinamenlänge um eine erhöhen
dta01 lda #$01 ; ---- logische geräteadressen in den akku laden
ldx #$08 ; ---- primäradresse in das x-register laden
ldy #$62 ; ---- sekundäradresse in das y-register laden
jsr $ffba ; ---- setzen der geräteadressen (logische, primär- und sekundäradresse)
nam01 lda #$00 ; ---- länge des dateinamens in den akku laden
nam02 ldx #$00 ; ---- low-byte der ram-adresse des dateinamen in das x-register laden
nma03 ldy #>pbr01 ; ---- high-byte der ram-adresse des dateinamen in das y-register laden
jsr $ffbd ; ---- festlegen des dateinamens
; --------------------------------------------------------------
; ---- anzahl der geladenen dateien auf bildschirm ausgeben ----
; --------------------------------------------------------------
inc $057f ; ---- aktuelle scpu-ram adresse low-byte um einen verringern
lda $057f ; ---- aktuelle scpu-ram adresse low-byte in den akku laden
cmp #$3a ; ---- und akku auf 3a testen
bne num01 ; ---- wenn "3a" erreicht wurde wurde, dann
lda #$30 ; ---- #30 in den akku laden
sta $057f ; ---- und low-byte auf #30 "0" festlegen
inc $057e ; ---- aktuelle scpu-ram adresse high-byte um einen verringern
lda $057e ; ---- aktuelle scpu-ram adresse high-byte in den akku laden
cmp #$3a ; ---- und akku auf 3a testen
bne num01 ; ---- wenn "3a" erreicht wurde wurde, dann
lda #$30 ; ---- #30 in den akku laden
sta $057e ; ---- und high-byte auf #30 "0" festlegen
inc $057d ; ---- aktuelle scpu-ram adresse bank-byte um einen verringern
; ---------------------------------------------------
; ---- den ausgabebereich des dateinamen löschen ----
; ---------------------------------------------------
num01 ldx #$10 ; ---- x-register auf #10 festlegen. maximale dateinamenslänge
tru77 lda #$20 ; ---- akku auf #20 festlegen
sta $0529,x ; ---- und bildschirmbereich löschen
lda #$08 ; ---- wert für schriftfarbe in dan akku laden
sta $d929,x ; ---- farbram mit farbe xx beschreiben
dex ; ---- x-register um einen verringern
bpl tru77 ; ---- wenn x-register auf #ff, dann
; ------------------------------------------------------------------------
; ---- dateiname der aktuell zu ladende datei auf bildschirm ausgeben ----
; ------------------------------------------------------------------------
nam12 ldy #$00 ; ---- y-register auf #xx dateinamenslänge festlegen
dey ; ---- y-register um einen verringern
rrt01 lda ($bb),y ; ---- lade dateinemenszeichen
cmp #$3a ; ---- akku-wert mit #3a vergleichen
bcc gut04 ; ---- wenn der akku-wert höher als #39 ist, dann
sec ; ---- carry-flag setzen
sbc #$40 ; ---- und #40 subtrahieren. aus z.b. (#41 = ascii "a" wird #01 bildschirmdarstellung)
gut04 sta $0529,y ; ---- und im bildschirm anzeigen
dey ; ---- dateinamenslänge um einen verringern
bpl rrt01 ; ---- wenn dateinamen komlett auf bildschirm angeszeigt wurde, dann
; ------------------------------------------------------------------------
; ---- hier beginnt die laderoutine. eine datei in das scpu-ram laden ----
; ------------------------------------------------------------------------
jsr $ffc0 ; ---- open: logische datei öffnen
lda #$08 ; ---- geräteadresse #08
jsr $ffb4 ; ---- talk auf den seriellen bus senden
lda #$62 ; ---- sekundäradresse in den akku laden
jsr $ff96 ; ---- übertragung der sekundäradresse nach talk-befehl
jsr $ee13 ; ---- byte vom seriellen bus lesen. low-byte der datei-ladeadresse
taa01 sta tab03 ; ---- low-byte datei-ladeadressen in tabelle eintragen
lda taa01+1 ; ---- aktuelle offset-adresse der datei-ladeadressen low-byte in den akku laden
clc ; ---- carry-flag löschen
adc #$02 ; ---- und zwei hinzuaddieren
sta taa01+1 ; ---- die summe als nächsten low-byte offset festlegen
bcc tst02 ; ---- wurde das carry-flag gesetzt?
inc taa01+2 ; ---- dann die aktuelle high-byte offset-adresse der datei-ladeadressen tabelle um einen
tst02 jsr $ee13 ; ---- byte vom seriellen bus lesen. high-byte der datei-ladeadresse
taa02 sta tab03+1 ; ---- high-byte datei-ladeadressen in tabelle eintragen
lda taa02+1 ; ---- aktuelle offset-adresse der datei-ladeadressen low-byte in den akku laden
clc ; ---- carry-flag löschen
adc #$02 ; ---- und zwei hinzuaddieren
sta taa02+1 ; ---- die summe als nächsten low-byte offset festlegen
bcc cst02 ; ---- wurde das carry-flag gesetzt?
inc taa02+2 ; ---- dann die aktuelle high-byte offset-adresse der datei-ladeadressen tabelle um einen
cst02 jsr $ee13 ; ---- ein datenbyte vom seriellen bus laden
scp87 sta [$fd] ; ---- ein byte in das scpu-ram schreiben
jsr bnz01 ; ---- aktuelle scpu-ramadresse auf bildschirm ausgeben
inc $d020 ; ---- ladeeffekte
dec $d020 ; ---- ladeeffekte
bit $90 ; ---- datei schon geladen
bvs cst01 ; ---- wenn ja, weiter ab cst01
inc tab00 ; ---- 16bit puffer für byte länge. low-byte um einen erhöhen
bne cst04 ; ---- ist carry-flag gesetzt?
inc tab00+1 ; ---- 16bit puffer für byte länge der datei. high-byte um einen erhöhen
cst04 inc $fd ; ---- ladeadresse low-byte um einen erhöhen
bne cst02 ; ---- ist das carry-flag gesetzt?
inc $fe ; ---- dann ladeadresse high-byte um einen erhöhen
bne cst02 ; ---- ist das carry-flag gesetzt?
inc $ff ; ---- dann ladeadresse bank-byte um einen erhöhen
bne cst02 ; ---- hier wird das carry-flag niemals gesetzt
cst01 lda #$01 ; ---- wert für offenen kanal laden
jsr $ffc3 ; ---- kanal schließen
inc $fd ; ---- ist die datei geladen, dann die ladeadresse low-byte um einen erhöhen
bne dst01 ; ---- ist das carry-flag gesetzt?
inc $fe ; ---- dann die ladeadresse high-byte um einen erhöhen
bne dst01 ; ---- ist das carry-flag gesetzt?
inc $ff ; ---- dann die ladeadresse bank-byte um einen erhöhen
; ----------------------------------------------------------------
; ---- byte-werte für die dateigröße in die tabelle eintragen ----
; ----------------------------------------------------------------
dst01 ldx #$00 ; ---- x-indizierung der tabelle für die byte-längen der dateien
lda tab00 ; ---- bytelänge aus puffer laden low-byte
tst03 sta tab01,x ; ---- bytelänge in tabelle eintragen low-byte
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
bne tst04 ; ---- ist das carry-flag gesetzt?
inc tst03+2 ; ---- dann das high-byte des low-byte tabellen-offset um einen erhöhen
inc tst05+2 ; ---- dann das high-byte des tabellen-offset high-byte um einen erhöhen
tst04 lda tab00+1 ; ---- bytelänge aus puffer laden. high-byte
tst05 sta tab01,x ; ---- high-byte bytelänge in die tabelle eintragen
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
bne tst06 ; ---- ist das carry-flag gesetzt?
inc tst03+2 ; ---- dann das high-byte des low-byte tabellen-offset um einen erhöhen
inc tst05+2 ; ---- dann das high-byte des tabellen-offset high-byte um einen erhöhen
tst06 stx dst01+1 ; ---- aktuelle x-indizierung für nächsten tabelleneintrag puffern
; ------------------------------------------------------------------------------------
; ---- byte-werte für die datei-ladeadressen im scpu-ram in die tabelle eintragen ----
; ------------------------------------------------------------------------------------
dst02 ldx #$03 ; ---- x-indizierung der scpu-ram tabelle
lda $fd ; ---- low-byte in den akku laden
tst10 sta tab02,x ; ---- und in die tabelle eintragen
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
bne tst11 ; ---- ist das carry-flag gesetzt?
inc tst10+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse low-byte um einen erhöhen
inc tst12+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse high-byte um einen erhöhen
inc tst13+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse bank-byte um einen erhöhen
tst11 lda $fe ; ---- high-byte in den akku laden
tst12 sta tab02,x ; ---- und in die tabelle eintragen
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
bne tst14 ; ---- ist das carry-flag gesetzt?
inc tst10+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse low-byte um einen erhöhen
inc tst12+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse high-byte um einen erhöhen
inc tst13+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse bank-byte um einen erhöhen
tst14 lda $ff ; ---- bank-byte in den akku laden
tst13 sta tab02,x ; ---- und in die tabelle eintragen
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
bne tst15 ; ---- ist das carry-flag gesetzt?
inc tst10+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse low-byte um einen erhöhen
inc tst12+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse high-byte um einen erhöhen
inc tst13+2 ; ---- dann das high-byte der scpu-ram tabellen-offset adresse bank-byte um einen erhöhen
tst15 stx dst02+1 ; ---- aktuelle x-indizierung für nächsten tabelleneintrag puffern
; --------------------------------------------------------------------------------------------
; ---- tabellen start- und endadressen werden in der tabelle der save-routine eingetragen ----
; --------------------------------------------------------------------------------------------
lda cab01+1 ; ---- lade low-byte adresse der tabelle für die dateinamenlänge
bne hib01 ; ---- wenn der akku #00 ist, dann
dec cab01+2 ; ---- aktuelle offset-adresse der dateinamen länge high-byte um einen verringern
hib01 dec cab01+1 ; ---- aktuelle offset-adresse der dateinamen länge low-byte um einen verringern
lda cab01+2 ; ---- lade high-byte adresse der tabelle für die dateinamenlänge in den akku
cmp #$a0 ; ---- wert für start offset in den akku laden
bne tre01 ; ---- wenn der start offset erreich wurde, dann
lda cab01+1 ; ---- aktuellen wert für start offset low-byte in den akku laden
bne tre01 ; ---- wenn die aktuelle offset-adrsse nicht #00 ist, dann nächste datei laden
lda cab02+1 ; ---- dann offset-adresse der dateinamen tabelle low-byte in den akku laden
sta tal01+6 ; ---- und in der tabelle für die save-routine eintragen
lda cab02+2 ; ---- dann offset-adresse der dateinamen tabelle high-byte in den akku laden
sta tal01+7 ; ---- und in der tabelle für die save-routine eintragen
lda dst01+1 ; ---- aktuelle x-indizierung der byte-länge als low-byte in den akku laden
sta tal01+10 ; ---- und in der tabelle für die save-routine eintragen
lda tst03+2 ; ---- offset-adresse der datei bytelängen tabelle high-byte in den akku laden
sta tal01+11 ; ---- und in der tabelle für die save-routine eintragen
lda dst02+1 ; ---- aktuelle x-indizierung der scpu-ram tabelle in den akku laden
sta tal01+14 ; ---- und in der tabelle für die save-routine eintragen
lda tst10+2 ; ---- high-byte adresse der scpu-ram tabelle in den akku laden
sta tal01+15 ; ---- und in der tabelle für die save-routine eintragen
lda taa01+1 ; ---- offset der datei-ladeadresse in tabelle eintragen low-byte
sta tal01+18 ; ---- und in der tabelle für die save-routine eintragen
lda taa01+2 ; ---- offset der datei-ladeadresse in tabelle eintragen high-byte
sta tal01+19 ; ---- und in der tabelle für die save-routine eintragen
rts ; ---- alles geladen.
tre01 jmp xwe02 ; ---- nächste datei laden
; ----------------------------------------------------------------------
; ---- es werden die dateinamen, die start- und endadresse aller ----
; ---- tabellen in den parameterpuffer der save-routine eingetragen ----
; ----------------------------------------------------------------------
sax01 jsr asr01 ; ---- endadresse der save-datei in routine eintragen
lda #$00 ; ---- init-wert in den akku laden
sta $fc ; ---- save-startadresse bank-byte auf $00 setzen
sta $ff ; ---- save-endadresse bank-byte auf $00 setzen
sgr01 ldx #$00 ; ---- x-indizierung begint ab #$00
lda tal01,x ; ---- gepufferte werte in routine einfügen
sta $fa ; ---- save-startadresse low-byte festlegen
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
lda tal01,x
sta $fb ; ---- save-startadresse high-byte festlegen
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
lda tal01,x
sta $fd ; ---- save-endadresse low-byte festlegen
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
lda tal01,x
sta $fe ; ---- save-endadresse high-byte festlegen
inx ; ---- x-indizierung für nächsten eintrag um einen erhöhen
stx sgr01+1 ; ---- wert der x-indizierung für nächste datei puffern
lda nlo01+1
clc
adc #$0b ; ---- adressabstand für den nächsten dateinamen addieren
sta nlo01+1 ; ---- und festlegen
bcc ete01
inc hlo01+1 ; ---- high-byte adresse des directory namen um einen erhöhen
ete01 jsr asr02 ; ---- tabelle abspeichen
dec cou01 ; ---- counter um einen verringern
bne sgr01 ; ---- schon alle tabellen abgespeichert?
rts ; ---- wenn ja, zurück zur hauptroutine
; -----------------------------------------------------
; ---- ram-endadresse in die save-routine einfügen ----
; -----------------------------------------------------
asr01 lda tst10+2 ; ---- high-byte offset in den akku laden
sta hby01+2 ; ---- high-byte in routine eintragen
sta hby02+2 ; ---- high-byte in routine eintragen
sta hby03+2 ; ---- high-byte in routine eintragen
ldx dst02+1 ; ---- aktuelle x-indizierung der scpu-ram tabelle in das x-register laden
dex ; ---- x-register um einen verringern
hby01 lda tab02,x ; ---- bank-byte der letzten geladenen datei aus tabelle beziehen.
sta xnd03+1 ; ---- und in der save-routine eintragen
dex ; ---- x-register um einen verringern
hby02 lda tab02,x ; ---- high-byte der letzten geladenen datei aus tabelle beziehen.
sta xnd02+1 ; ---- und in der save-routine eintragen
dex ; ---- x-register um einen verringern
hby03 lda tab02,x ; ---- low-byte der letzten geladenen datei aus tabelle beziehen.
sta xnd01+1 ; ---- und in der save-routine eintragen
; --------------------------
; ---- die save-routine ----
; --------------------------
lda #$03 ; ---- wert für bank $03 in den akku laden
sta afc ; ---- startadresse bank-byte der save-datei festlegen
xnd03 lda #$00 ; ---- scpu bank-byte endadresse der save-datei in den akku laden
sta aff ; ---- und festlegen
ldx #$00
ldy #$00
stx afa ; ---- startadresse low-byte der save-datei
sty afb ; ---- startadresse high-byte der save-datei
xnd01 ldx #$00 ; ---- endadresse low-byte der save-datei
xnd02 ldy #$00 ; ---- endadresse high-byte der save-datei
stx afd
sty afe
asr02 lda #$0b ; ---- dateinamenlänge aller tabellen
nlo01 ldx #<pam01 ; ---- adresse des dateinamen low-byte
hlo01 ldy #>pam01 ; ---- adresse des dateinamen high-byte
jsr $ffbd ; ---- festlegen des dateinamens
ldx #$08
ldy #$61
jsr $fe00 ; ---- setzen der geräteadressen (logische, primär- und sekundäradresse)
jsr $f3d5 ; ---- datei öffnen auf seriellem bus
jsr $f25b ; ---- weiter in originaler chkout-routine
lda afa
jsr $eddd ; ---- ciout: gibt ein byte auf seriellem bus aus
lda afb
jsr $eddd ; ---- ciout: gibt ein byte auf seriellem bus aus
bcf47 lda [$fa] ; ---- wenn unter dem kernal abgespeichert wird bitte "bei $01=#37 sei,inc $01,dec $01,cli"
ldy afa
cpy afd
bne bcf67
ldy afb
cpy afe
bne bcf67
ldy afc
cpy aff
beq bcf76
bcf67 jsr $eddd ; ---- ciout: gibt ein byte auf seriellem bus aus
inc afa
bne bcf47
inc afb
bne bcf47
inc afc
bne bcf47
bcf76 jsr $f63f ; ---- sendet unlisten und close befehl zum serial bus.
jmp $f6f3 ; ---- ein- ausgabe zurücksetzen
; ---------------------------------------------------------------------------------------
; ---- hex to ascii konverter. ausgabe der aktuellen scpu-ram adresse auf bildschirm ----
; ---------------------------------------------------------------------------------------
bnz01 ldx #$00 ; ---- bildschirmadresse plus #00
lda $ff ; ---- bank-byte hexwert in akku laden
jsr srt44 ; ---- nach ascii konvertieren und ausgeben
ldx #$02 ; ---- bildschirmadresse plus #02
lda $fe ; ---- high-byte hexwert in akku laden
jsr srt44 ; ---- nach ascii konvertieren und ausgeben
ldx #$04 ; ---- bildschirmadresse plus #04
lda $fd ; ---- low-byte hexwert in akku laden
; -----------------------------------------------------------------
; ---- hex nach ascii konverter z.b. (hex #4e = #34,#45 = "4e") ----
; -----------------------------------------------------------------
srt44 pha
lsr
lsr
lsr
lsr
jsr bla33
pla
and #$0f
bla33 ora #$30
cmp #$3a
bcc hak99
adc #$06
and #$0f ; ---- der befehl ist nur für die anzeige im bildschirmspeicher
hak99 jsr ern85
rts
ern85 sta $0489,x ; ---- ausgabeadresse auf bildschirm plus x-register
inx
rts
pam01 !text "BIG RAMFILE" ; ---- dateiname aller auf ein d81-image zusammengelinkten dateien
!text "NAME LENGTH" ; ---- tabelle für die dateinamenlänge
!text "FILE NAMES" ; ---- tabelle für die dateinamen
!text "BYTE LENGTH" ; ---- tabelle für die dateigröße
!text "RAM ADDRESS" ; ---- tabelle für die dateiadresse im scpu-ram
!text "FILE ADDRES" ; ---- tabelle für die datei-ladeadresse
!text "SCPU-DIRECT" ; ---- name des internen scpu-directory
set01 !byte $23 ; ---- "#"
!byte $55,$31,$20 ; ---- "u1 "
!byte $32,$20,$30 ; ---- " 2 0"
!byte $20,$34,$30 ; ---- " 40"
!byte $20,$30,$31 ; ---- " 03"
tal01 !byte $00,$a0 ; ---- ram-startadresse der tabelle für die namenslänge der dateien
!byte $1c,$a0 ; ---- ram-endadresse der tabelle für die namenslänge der dateien
!byte $00,$b0 ; ---- ram-startadresse der tabelle für die dateinamen
!byte $ac,$b0 ; ---- ram-endadresse der tabelle für die dateinamen
!byte $00,$20 ; ---- ram-startadresse der tabelle für die byte-länge der dateien
!byte $38,$20 ; ---- ram-endadresse der tabelle für die byte-länge der dateien
!byte $00,$30 ; ---- ram-startadresse der tabelle für die scpu-ram adressen der dateien
!byte $57,$30 ; ---- ram-endadresse der tabelle für die scpu-ram adressen der dateien
!byte $00,$90 ; ---- ram-startadresse der tabelle für die ladeadressen der dateien
!byte $00,$90 ; ---- ram-endadresse der tabelle für die ladeadressen der dateien
cou01 !byte $05 ; ---- downcounter für die anzahl der tabelle
fle01 !byte $00,$00 ; ---- puffer für die anzahl der verarbeiteten dateinamen
trn18 !byte $14,$15,$12,$0e,$20,$04,$09,$13
!byte $0b,$20,$01,$0e,$04,$20,$10,$12
!byte $05,$13,$13,$20,$13,$10,$01,$03,$05
trn25 !byte $14,$0f,$20,$13,$01,$16,$05,$20
!byte $14,$08,$05,$20,$0c,$09,$0e,$0b
!byte $05,$04,$20,$06,$09,$0c,$05,$20
!byte $01,$0e,$04,$20,$14,$08,$05,$20
!byte $14,$01,$02,$0c,$05,$13
trn0c !byte $0c,$0f,$01,$04,$09,$0e,$07,$20
!byte $06,$09,$0c,$05,$13
trn0e !byte $0e,$15,$0d,$02,$05,$12,$20,$0f
!byte $06,$20,$06,$09,$0c,$05,$13
buf80 !byte $00 ; ---- overflow-puffer
bff01 !byte $00,$00 ; ---- additions-puffer 1. auch die endadresse des directory
bff02 !byte $00,$b0 ; ---- additions-puffer 2
ppp01 !byte $00,$00 ; ---- anzahl dateinamen

Alles anzeigen

Stephan Scheuer · 30. April 2019

Zitat von mrr19121970

This is the method I use.

I don't use these tools:

linking is done by TAS code only.

you are also a professional and self-taught.

Anpassung alter Loader ans Easyflash u.a.

Ähnliche Themen

Easyflash Games - Echte Anpassungen

Easyflash Wishlist