Einzelnes 2x2 Tile setzen

Soulstealer · 5. Juni 2018

Momentan stehe ich vor dem Problem, einigermaßen elegant ein einzelnes 2x2 Tile auf den Bildschirm zu bringen
Ich verbrauche irgendwie jede menge Speicher für vier Tabellen jeweils (Hi+Low Screen+Colormem), sowie danach noch einiges an ZP Addition.
Bei meinem (2x2) Screen gibt es 19 Spalten in 11 Zeilen (der erste und letzte Char bleibt immer leer, angefangen wird ab Zeile 2).

Das Rendern des gesamten Screens braucht als (halber) Speedcode nur m.M.n. schlanke ~734 kb (Syntax ist C64 Studio)

Code

render_complete:
lda #19
sta counter
-
!for ROW = 0 to 11
ldy counter
lda level_cache+(ROW*19),y
tax
lda counter
asl ; multiply by 2
tay
lda TILE_CHARS_0_0,x
sta screen+39+(ROW*80),y
lda TILE_CHARS_1_0,x
sta screen+40+(ROW*80),y
lda TILE_CHARS_0_1,x
sta screen+79+(ROW*80),y
lda TILE_CHARS_1_1,x
sta screen+80+(ROW*80),y
lda TILE_COLORS_0_0,x
sta $d800+39+(ROW*80),y
lda TILE_COLORS_1_0,x
sta $d800+40+(ROW*80),y
lda TILE_COLORS_0_1,x
sta $d800+79+(ROW*80),y
lda TILE_COLORS_1_1,x
sta $d800+80+(ROW*80),y
!end
dec counter
beq +
jmp -
+
rts

Alles anzeigen

Hat da jemand einen Tipp/Rant oder Beispielsource, wie man das schöner/schneller/kleiner machen kann?

Squidward · 5. Juni 2018

Ohne angeschaut zu haben... die Coloram Tabelle kannst dir doch sparen, low ist immer gleich wie Screen Low und Hi musst du nur entsprechend auf das Screen Hi rechnen...

Mac Bacon · 6. Juni 2018

Zitat von Soulstealer

Ich verbrauche irgendwie jede menge Speicher für vier Tabellen jeweils

Ob Du die Tabellen wirklich brauchst, hängt vom Aussehen Deiner Tiles ab. Bei 2x2-Charsets oder so simplen Grafiken wie bei Boulder Dash käme man wohl ohne Tabellen aus, da man Tile "n" einfach immer aus den Chars n, n+64, n+128 und n+192 zusammensetzen kann.
Mit Tabellen lassen sich die Tiles dagegen beliebig zusammensetzen.

Zitat von Soulstealer

Code

ldy counter

lda level_cache+(ROW*19),y

tax

lda counter

asl ; multiply by 2

tay

Idee 1: Statt "lda counter" reicht hier auch "tya".
Idee 2: Das mehrfache Verdoppeln von "counter" im Speedcode ist überflüssig - einfach einmal vor dem Speedcode machen und in die ZP schreiben, dann reduziert sich das Verdoppeln auf "ldy cached_write_counter".
Idee 3: Der Lesezähler "counter" zählt von 19 bis 0 in Einerschritten, während der Schreibzähler in Zweierschritten zählt. Am Schreibzähler kann man bei 2x2 nichts ändern, aber durch Interleaving der Leveldaten könnte man den Schreibzähler auch gleich zum Lesen benutzen. Dann fällt das Verdoppeln komplett weg, nur der Initialwert wäre anders und DEC müsste zweimal statt einmal ausgeführt werden.

Soulstealer · 6. Juni 2018

@Mac Bacon
Danke schon mal für die Tipps, die habe ich direkt umgesetzt. Aber das Rendern des kompletten screens war ja schon relativ flott und kommt ja ohne Tabellen aus.
Ich habe nur keine gute Lösung ein einzelnes Tile neu zu setzen, z.B. wenn man was einsammelt und das vom screen verschwindet.
Dank @Squidwards Tipp brauche ich zumindest zwei Tabellen weniger. Trotzdem rechne ich da noch für meinen Gechmack zu viel, dafür dass ich zwei Tabellen als 'Cache' habe.

Edit: Das mit dem Interleaving habe ich noch nicht so ganz verstanden. Wie sollten die Daten denn da am besten abgelegt werden?

Edit2: Ah, ich glaube ich habe das mit dem Interleaving doch verstanden. Naja, bei mir passt ein Level in 228 bytes. das kann ich natürlich schön X\Y indiziert abrufen, dass wäre ja dann nicht mehr möglich, da ich über 256bytes kommen würde.

Edit3: ok war wohl doch noch falsch. Der Ansatz ist wohl eher das in zwei 114er Tabellen zu aufzuteilen, sagen wir mal A und B und dann immer ABABABABA abzulegen. Dann kann ich da in Zweierschritten durch und muss nur nach der Hälfte wieder auf den anfang+1 setzen?

M. J. · 6. Juni 2018

Zitat von Soulstealer

lda level_cache+(ROW*19),y
tax

Trotz der Klammer im Ausdruck gehe ich davon aus, daß es sich hier um eine absolute Adresse handelt, so daß man beim Laden (anders als beim Speichern) auch kürzer "LDX level_cache+(ROW*19),y" schreiben kann.

Soulstealer · 8. Juni 2018

So, nachdem ich mich ein wenig reingefuchst hatte, habe ich die für mich kleine und schnelle Lösung zum setzen eines 2x2 Tiles gefunden. Zuerst hatte ich natürlich den Ansatz mit der X indizierten ZP Adresse, aber da musste ich natürlich jedesmal inx dann nach a kopieren u adc #$40 machen. Außerdem brauchte ich mindestens zwei Tabellen und musste das HI byte vorher ausrechnen.

Mein Ansatz beruht darauf, dass ich ja den Screen mit vier festen X indizierten Werten erreichen kann. Also, habe ich nur die relative Adresse des Tiles abgespeichert (bei mir 19x11, geht aber auch bis zu 20x11, Hauptsache unter 255!)

Code

set_one_tile_x
lda address_mod,x
ldy level_cache+1,x
cpx #(1*57)
bcs +
;jumper_0
tax
lda TILE_CHARS_0_0,y
sta screen+(0*240)+39,x
lda TILE_CHARS_1_0,y
sta screen+(0*240)+40,x
lda TILE_CHARS_0_1,y
sta screen+(0*240)+79,x
lda TILE_CHARS_1_1,y
sta screen+(0*240)+80,x
lda TILE_COLORS_0_0,y
sta $d800+39+(0*240),x
lda TILE_COLORS_1_0,y
sta $d800+40+(0*240),x
lda TILE_COLORS_0_1,y
sta $d800+79+(0*240),x
lda TILE_COLORS_1_1,y
sta $d800+80+(0*240),x
rts
+
cpx #(2*57)
bcs +
;jumper_1
tax
lda TILE_CHARS_0_0,y
sta screen+(1*240)+39,x
lda TILE_CHARS_1_0,y
sta screen+(1*240)+40,x
lda TILE_CHARS_0_1,y
sta screen+(1*240)+79,x
lda TILE_CHARS_1_1,y
sta screen+(1*240)+80,x
lda TILE_COLORS_0_0,y
sta $d800+39+(1*240),x
lda TILE_COLORS_1_0,y
sta $d800+40+(1*240),x
lda TILE_COLORS_0_1,y
sta $d800+79+(1*240),x
lda TILE_COLORS_1_1,y
sta $d800+80+(1*240),x
rts
+
cpx #(3*57)
bcs +
;jumper_2
tax
lda TILE_CHARS_0_0,y
sta screen+(2*240)+39,x
lda TILE_CHARS_1_0,y
sta screen+(2*240)+40,x
lda TILE_CHARS_0_1,y
sta screen+(2*240)+79,x
lda TILE_CHARS_1_1,y
sta screen+(2*240)+80,x
lda TILE_COLORS_0_0,y
sta $d800+39+(2*240),x
lda TILE_COLORS_1_0,y
sta $d800+40+(2*240),x
lda TILE_COLORS_0_1,y
sta $d800+79+(2*240),x
lda TILE_COLORS_1_1,y
sta $d800+80+(2*240),x
rts
+
; cpx #(3*57)
; bcs +
;jumper_3
tax
lda TILE_CHARS_0_0,y
sta screen+(3*240)+39,x
lda TILE_CHARS_1_0,y
sta screen+(3*240)+40,x
lda TILE_CHARS_0_1,y
sta screen+(3*240)+79,x
lda TILE_CHARS_1_1,y
sta screen+(3*240)+80,x
lda TILE_COLORS_0_0,y
sta $d800+39+(3*240),x
lda TILE_COLORS_1_0,y
sta $d800+40+(3*240),x
lda TILE_COLORS_0_1,y
sta $d800+79+(3*240),x
lda TILE_COLORS_1_1,y
sta $d800+80+(3*240),x
rts
address_mod:
!for elements = 0 to 3
!for ROW = 0 to 2
!for COL = 0 to 18
!byte (ROW*80)+(2*COL)+2
!end
!end
!end

Alles anzeigen

Also m.M.n. ist der Weg schon ziemlich der Beste. Wenig Rechnerei und nur eine Table. Man könnte evtl. noch was sparen, wenn man den Wert am Anfang evtl. in A statt in X ablegt.