Assembler (Spiele-) Tutorial für C16 und Plus/4

cbmhardware · 6. März 2017

Gibt es ein Assembler Tutorial zur Spiele-Programmierung für den C16 und Plus/4 ?

Also bewegliche Objekte: Bobs ..? , Raster-IRQ, Softscrolling und solche Sachen ?

Sound habe ich schon selbst durch Reassembling herausgefunden. - Ich werde doch nicht alles andere auch so mühsam aus alten Programmen herauspopeln müssen ?

Das spielt die Melodie von Kikstart 1. Hat leider einen kleinen Fehler beim Wrap-around, also beim erneuten Abspielen, den ich nicht finden kann. Ein Piepser zu viel. Vielleicht kommt jemand drauf ... ?

Code

!to"ksnd.prg",cbm
TEDSND1 = $FF0E ; $FF0E: TED Sound Voice #1 L
TEDSND2 = $FF0F ; $FF0F: TED Sound Voice #2 L
TEDSND2H = $FF10 ; $FF10: TED Sound Voice #2 H
TEDSND = $FF11 ; $FF11: TED Sound Volume,on/off,Wave,D/A
TEDREG = $FF12 ; $FF12: TED Register (Voice #1 H)
TEDBACK = $FF15 ; $FF15: Background-Color
TEDFRAME = $FF19 ; $FF19: TED FRAME
*= $1001
!byte $0c,$10,$0a,$00,$9e,$34,$31,$30,$39,$00,$00,$00
*=$100d
sei
lda #$93
jsr $ffd2
ldx #$0f
- lda txt,x
sta $0c00,x
dex
bpl -
lda #$00
sta $34
sta $35
loop:
jsr player
ldx #$00 ; waste time
-- ldy #$00
- dey
bne -
inx
cpx #$10
bne --
jmp loop
player:
inc $34
lda $34
cmp #$06 ; 6 cycles
bne +
lda #$00
sta $34
inc $35
lda $35
cmp #$c0 ; 192 cycles
bne +
lda #$00
sta $35
+ ldx $35
lda offset,x ; get offset
and #$F0 ; mask to msb
lsr
lsr
lsr
lsr
tay
lda voice1l,y ; get data for voice 1 L
sta TEDSND1
lda voice1h,y ; get data for voice 1 H
and #$03
ora TEDREG
sta TEDREG ; set voice 1 H
lda offset,x
and #$0F ; mask to lsb
tay
lda voice2l,y ; get data for voice 2 L
sta TEDSND2
lda voice2h,y
sta TEDSND2H ; get data for voice 2 H
lda #$38
sta TEDSND ; volume: 0
rts
txt:
!scr "kikstart 1 sound"
offset:
!by $91,$91,$91,$94,$94,$94,$72,$72,$72,$74,$74,$74,$41,$41,$41,$44,$44,$44,$72,$72,$92,$d4,$d4,$94,$c4,$c4,$c4,$b8,$b8,$b8,$a6,$a6,$86,$88,$88,$88,$64,$64,$64,$68
!by $68,$68,$66,$66,$66,$68,$68,$68,$84,$84,$84,$88,$88,$88,$66,$66,$66,$68,$68,$68,$44,$44,$44,$48,$48,$48,$66,$66,$86,$d8,$d8,$e8,$d3,$d3,$d3,$c7,$c7,$c7,$a5,$a5
!by $95,$97,$97,$97,$c4,$c4,$c4,$a8,$a8,$a8,$96,$96,$86,$88,$88,$88,$91,$91,$91,$94,$94,$94,$72,$72,$72,$74,$74,$74,$41,$41,$41,$44,$44,$44,$72,$72,$92,$d4,$d4,$94
!by $c4,$c4,$c4,$b8,$b8,$b8,$a6,$a6,$86,$88,$88,$88,$64,$64,$64,$68,$68,$68,$66,$66,$66,$68,$68,$68,$c4,$c4,$c4,$b8,$b8,$b8,$a6,$a6,$86,$88,$88,$88,$64,$64,$64,$68
!by $68,$68,$46,$46,$46,$48,$48,$48,$71,$71,$71,$74,$74,$74,$72,$72,$72,$74,$74,$74,$71,$71,$e2,$74,$74,$74,$72,$72,$72,$74,$74,$74,$00
voice1l:
!by $00,$00,$00,$00,$04,$20,$38,$43,$58,$6a,$73,$7b,$82,$90,$9c,$00
voice1h:
!by $00,$00,$00,$00,$03,$03,$03,$03,$03,$03,$03,$03,$03,$03,$03,$00
voice2l:
!by $00,$0d,$a9,$ca,$08,$3f,$70,$87,$b0,$00,$00,$00,$00,$00,$00,$00
voice2h:
!by $00,$01,$01,$01,$02,$02,$02,$02,$02,$00,$00,$00,$00,$00,$00,$00

Alles anzeigen

Hexworx · 6. März 2017

Zitat von cbmhardware

Vielleicht kommt jemand drauf ... ?

Das $e2 in Zeile 90.

cbmhardware · 7. März 2017

Ah, Danke, genau das war es. Manchmal sieht man den Wald vor Bäumen nicht.

Da hier ansonsten nichts kommt, werde ich Kikstart mal weiter sezieren.

Habe noch am IRQ gebogen, etwas Border Luma-Flash und eine Tastatur-Abfrage eingebaut. Dann kann es auch beendet werden.

Code

!to"ksnd.prg",cbm
TEDSND1 = $FF0E ; $FF0E: TED Sound Voice #1 L
TEDSND2 = $FF0F ; $FF0F: TED Sound Voice #2 L
TEDSND2H = $FF10 ; $FF10: TED Sound Voice #2 H
TEDSND = $FF11 ; $FF11: TED Sound Volume,on/off,Wave,D/A
TEDREG = $FF12 ; $FF12: TED Register (Voice #1 H)
TEDBACK = $FF15 ; $FF15: Background-Color
TEDFRAME = $FF19 ; $FF19: TED FRAME
;------------------------------------------------------
;
; Commdore C16 Kikstart Game-Sound
;
; Original-Player: $2aa0
;
; Reassembly and rework: 6.3.2017, M. Sachse
;
; http://www.cbmhardware.de
;
;-------------------------------------------------------
*= $1001
!byte $09,$10,$0a,$00,$9e,$34,$31,$30,$39,$00,$00,$00
*=$100d
sei
lda #$ee
sta TEDFRAME
lda #$1b
sta $ff06
lda #$93
jsr $ffd2
ldx #$21
- lda txt,x
sta $0c00,x
dex
bpl -
lda #$00
sta $34
sta $35
lda #<loop ; new irq
sta $0314
lda #>loop
sta $0315
cli
rts
exit: sei
lda #$00
sta TEDSND ; volume: 0
sta $02FE
sta $02FF
lda #$b3 ; system irq
sta $0314
lda #$fc
sta $0315
jsr $FF84 ; Initialize I/O devices
jsr $FF87 ; RAM Test
jsr $FF8A ; Restore vectors to initial values
jsr $FF81 ; Initialize screen editor
jmp $8000 ; cold start
loop: jsr player
ldx #$00 ; waste time
-- ldy #$00
- dey
bne -
inx
cpx #$10
bne --
key: lda #$7f
sta $fd30
sta $ff08
lda $ff08
cmp #$ef
beq exit
bne loop
player: inc $34
lda $34
cmp #$06 ; 6 cycles
bne +
lda #$00
sta $34
inc $35
lda $35
cmp #$c0 ; 192 cycles
bne +
lda #$00
sta $35
+ ldx $35
lda offset,x ; get offset
and #$F0 ; mask to msb
lsr ; shift ..
lsr ; .. down ..
lsr ; .. to ..
lsr ; .. lsb
tay
lda voice1l,y ; get data for voice 1 L
sta TEDSND1
and #%01110000
ora #%11001110
sta TEDFRAME ; some border luma flashing
lda voice1h,y ; get data for voice 1 H
and #$03
ora TEDREG
sta TEDREG ; set voice 1 H
lda offset,x
and #$0F ; mask to lsb
tay
lda voice2l,y ; get data for voice 2 L
sta TEDSND2
lda voice2h,y
sta TEDSND2H ; get data for voice 2 H
lda #$38
sta TEDSND ; volume: 0
rts
txt:
!scr "kikstart 1 sound - space to quit !"
; --- table offsets
offset:
!by $91,$91,$91,$94,$94,$94,$72,$72,$72,$74,$74,$74,$41,$41,$41,$44,$44,$44,$72,$72,$92,$d4,$d4,$94,$c4,$c4,$c4,$b8,$b8,$b8,$a6,$a6,$86,$88,$88,$88,$64,$64,$64,$68
!by $68,$68,$66,$66,$66,$68,$68,$68,$84,$84,$84,$88,$88,$88,$66,$66,$66,$68,$68,$68,$44,$44,$44,$48,$48,$48,$66,$66,$86,$d8,$d8,$e8,$d3,$d3,$d3,$c7,$c7,$c7,$a5,$a5
!by $95,$97,$97,$97,$c4,$c4,$c4,$a8,$a8,$a8,$96,$96,$86,$88,$88,$88,$91,$91,$91,$94,$94,$94,$72,$72,$72,$74,$74,$74,$41,$41,$41,$44,$44,$44,$72,$72,$92,$d4,$d4,$94
!by $c4,$c4,$c4,$b8,$b8,$b8,$a6,$a6,$86,$88,$88,$88,$64,$64,$64,$68,$68,$68,$66,$66,$66,$68,$68,$68,$c4,$c4,$c4,$b8,$b8,$b8,$a6,$a6,$86,$88,$88,$88,$64,$64,$64,$68
!by $68,$68,$46,$46,$46,$48,$48,$48,$71,$71,$71,$74,$74,$74,$72,$72,$72,$74,$74,$74,$71,$71,$71,$74,$74,$74,$72,$72,$72,$74,$74,$74
;--- sound frequency table
voice1l:
!by $00,$00,$00,$00,$04,$20,$38,$43,$58,$6a,$73,$7b,$82,$90,$9c,$00
voice1h:
!by $00,$00,$00,$00,$03,$03,$03,$03,$03,$03,$03,$03,$03,$03,$03,$00
voice2l:
!by $00,$0d,$a9,$ca,$08,$3f,$70,$87,$b0,$00,$00,$00,$00,$00,$00,$00
voice2h:
!by $00,$01,$01,$01,$02,$02,$02,$02,$02,$00,$00,$00,$00,$00,$00,$00

Alles anzeigen

cbmhardware · 7. März 2017

Das immer fehlende Titelbild aus den Kikstart Pfusch-Versionen 2 - "ganz viel" , die wohl mit dem Level-Editor entstanden waren. Das wird eine Art RLE-Enpacker sein ?
In den 1025 Bytes sind sowohl Screen- als auch Color-RAM Daten.

Kommentare sind in englischer Sprache. Möchte es irgendwann auf meine Webseite packen, wenn ich es ganz zerpflückt habe.

Code

!to"ktitle.prg",cbm
;----------------------------------------------------------
;
; Commdore C16 Kikstart Title
;
; Original-Routine: $2671-26bd
;
; Crunched Screen and Color-RAM Data: $24ed-$28d5
;
; Reassembly and rework: 7.3.2017, M. Sachse
;
; http://www.cbmhardware.de
;
;----------------------------------------------------------
*= $1001
!byte $09,$10,$0a,$00,$9e,$34,$31,$30,$39,$00,$00,$00
*=$100d
jsr display
jmp *
display:
LDA #$00
STA $FF15
STA $FF19 ; border and background to black
LDA #<title-1
STA $E0
LDA #>title
STA $E1
LDA #$E7
STA $E2
LDA #$0F ; target: $0fe7
STA $E3
LDY #$00
L268B: LDX #$01
LDA ($E0),Y ; fetch table byte
CMP #$04 ; #$04
BNE L269E ; not, write it to screen
JSR L26B5 ; check for $e0 = #$00
LDA ($E0),Y ; fetch table byte
TAX ; transfer to x-reg
JSR L26B5 ; check for $e0 = #$00
L269C: LDA ($E0),Y ; fetch table byte
L269E: STA ($E2),Y ; write table byte
LDA $E2 ; get target address low byte
BNE L26A6 ; not: #$00 go on
DEC $E3 ; dec taget high
L26A6: DEC $E2 ; dec target low byte
DEX ; check fetched byte for #$00
BNE L269C ; go on .. seems to be RLE-Encoding
JSR L26B5
LDA $E3
CMP #$07 ; check for target hi byte = #$07
BNE L268B ; not, go on
RTS ; else end
L26B5: LDA $E0 ; source low byte = #$00
BNE L26BB
DEC $E1 ; dec source high byte
L26BB: DEC $E0 ; dec source low byte
RTS
!by $33,$20,$21,$22,$00,$fc,$86,$04,$05,$06,$1d,$81,$a0,$b1,$55,$a8,$25,$b0,$f3,$00
!by $b1,$29,$86,$44,$78,$41,$dc,$8d,$88,$91,$1a,$21,$23,$03,$b1,$6d,$b1,$1a,$99,$ec
!by $31,$19,$19,$c0,$d1,$3d,$b8,$2c,$b9,$da,$1a,$a2,$1b,$1c,$f1,$64,$53,$8d,$04,$0d
!by $31,$64,$36,$88,$8e,$37,$38,$39,$1f,$93,$1d,$04,$1e,$1f,$00,$5c,$c3,$01,$02,$03
!by $07,$0f,$08,$09,$80,$e1,$d0,$19,$fd,$ff,$60,$c1,$fe,$ff,$96,$00,$09,$e1,$06,$d2
!by $20,$24,$47,$9a,$a8,$88,$91,$10,$10,$2d,$64,$47,$b9,$a8,$8b,$33,$30,$0a,$79,$91
!by $b0,$88,$91,$12,$22,$b9,$4e,$26,$99,$fd,$0f,$88,$d0,$f7,$e8,$98,$29,$0f,$f0,$14
!by $8a,$4a,$be,$33,$03,$2a,$26,$9f,$ca,$10,$fa,$79,$67,$03,$aa,$a5,$9f,$79,$9b,$03
!by $99,$9c,$03,$8a,$99,$68,$03,$a2,$04,$20,$00,$01,$99,$34,$03,$c8,$c0,$34,$d0,$d2
!by $a0,$00,$4c,$35,$01,$04,$00,$40,$a9,$00,$85,$9f,$e0,$01,$90,$1f,$46,$fd,$d0,$15
!by $48,$ad,$19,$01,$d0,$03,$ce,$1a,$01,$ce,$19,$01,$ad,$6a,$25,$90,$13,$6a,$85,$fd
!by $68,$2a,$26,$9f,$ca,$d0,$e1,$60,$ca,$c6,$ff,$c6,$af,$88,$b1,$ae,$91,$fe,$98,$d0
!by $f8,$8a,$d0,$f0,$88,$e8,$20,$08,$01,$4a,$c8,$90,$f8,$f0,$2b,$c0,$11,$b0,$56,$be
!by $33,$03,$20,$00,$01,$79,$67,$03,$85,$a7,$a5,$9f,$79,$9b,$03,$48,$d0,$06,$a4,$a7
!by $c0,$04,$90,$02,$a0,$03,$be,$9f,$01,$20,$00,$01,$79,$a2,$01,$a8,$a5,$a7,$e5,$fe
!by $90,$02,$c6,$ff,$49,$ff,$85,$fe,$c0,$01,$90,$91,$be,$34,$03,$20,$00,$01,$79,$68
!by $03,$90,$03,$e6,$9f,$18,$65,$fe,$85,$ae,$a5,$9f,$79,$9c,$03,$65,$ff,$85,$af,$68
!by $aa,$a4,$a7,$90,$95,$4c,$00,$20,$02,$04,$04,$30,$20,$10,$80,$00,$38,$b6,$ee,$b7
!by $be,$87,$eb,$ac,$ea,$9a,$aa,$fb,$84,$f9,$b5,$bf,$3a,$dd,$5f,$6c,$b6,$a3,$e6,$eb
!by $da,$df,$52,$92,$3f,$95,$cf,$09,$a9,$00,$8d,$15,$ff,$8d,$19,$ff,$a9,$d5,$85,$e0
!by $a9,$28,$85,$e1,$a9,$e7,$85,$e2,$a9,$0f,$85,$e3,$a0,$00,$a2,$01,$b1,$e0,$c9,$04
!by $d0,$0b,$20,$b5,$26,$b1,$e0,$aa,$20,$b5,$26,$b1,$e0,$91,$e2,$a5,$e2,$d0,$02,$c6
!by $e3,$c6,$e2,$ca,$d0,$f1,$20,$b5,$26,$a5,$e3,$c9,$07,$d0,$d7,$60,$a5,$e0,$d0,$02
!by $c6,$e1,$c6,$e0,$60,$00,$71,$1e,$04,$01,$32,$04,$03,$28,$04,$23,$28,$04,$33,$28
!by $04,$43,$28,$04,$53,$50,$04,$43,$28,$04,$33,$28,$04,$23,$28,$04,$03,$50,$04,$01
!by $50,$04,$71,$21,$04,$01,$57,$04,$71,$20,$04,$01,$d0,$04,$13,$27,$04,$01,$00,$02
!by $04,$ff,$02,$04,$00,$02,$04,$ff,$02,$04,$00,$02,$04,$ff,$02,$04,$00,$02,$04,$ff
!by $02,$04,$00,$02,$04,$ff,$02,$04,$00,$02,$04,$ff,$02,$04,$20,$09,$04,$0d,$01,$13
!by $14,$05,$12,$14,$12,$0f,$0e,$09,$03,$20,$10,$12,$05,$13,$05,$0e,$14,$13,$20,$32
!by $04,$a0,$f0,$c0,$25,$04,$ee,$a0,$ed,$c0,$14,$04,$ee,$a0,$f0,$c0,$0b,$04,$ee,$a0
!by $f0,$fd,$a0,$f0,$c0,$ee,$a0,$03,$04,$f0,$c0,$ee,$f0,$c0,$ee,$a0,$02,$04,$f0,$c0
!by $05,$04,$ee,$c2,$a0,$c2,$f0,$c0,$09,$04,$ee,$c2,$a0,$c2,$a0,$02,$04,$c7,$a0,$c7
!by $a0,$ce,$cd,$c7,$a0,$c7,$02,$04,$a0,$c7,$a0,$ce,$cd,$a0,$f0,$c0,$03,$04,$fd,$c7
!by $a0,$c7,$02,$04,$a0,$f0,$c0,$ee,$a0,$f0,$c0,$ee,$a0,$c7,$02,$04,$a0,$c7,$a0,$02
!by $04,$d4,$a0,$cc,$ce,$a0,$ce,$d4,$a0,$d4,$02,$04,$a0,$cc,$ce,$a0,$ce,$a0,$d4,$a0
!by $04,$04,$d4,$a0,$d4,$02,$04,$a0,$d4,$a0,$c7,$a0,$d4,$a0,$c7,$a0,$d4,$02,$04,$a0
!by $d4,$a0,$02,$04,$e5,$a0,$03,$04,$ce,$a0,$f4,$a0,$e5,$02,$04,$a0,$03,$04,$ce,$f4
!by $a0,$cc,$ef,$03,$04,$a0,$e5,$a0,$e5,$02,$04,$a0,$cc,$ef,$e5,$a0,$cc,$ef,$f4,$a0
!by $e5,$f4,$a0,$e5,$a0,$ea,$ef,$fa,$cd,$ef,$cd,$ea,$ef,$fa,$ea,$ef,$fa,$cd,$ef,$cd
!by $cc,$ef,$04,$04,$fa,$e7,$ef,$fa,$e7,$ef,$09,$04,$ce,$e7,$ef,$fa,$a0,$02,$04,$d9
!by $a0,$d9,$a0,$cd,$e0,$cd,$a0,$d9,$02,$04,$a0,$d9,$a0,$cd,$a0,$cd,$a0,$02,$04,$c8
!by $a0,$d9,$02,$04,$a0,$d9,$02,$04,$a0,$d9,$a0,$d9,$a0,$04,$04,$ce,$a0,$d9,$a0,$d9
!by $a0,$02,$04,$c8,$a0,$c8,$a0,$02,$04,$cd,$a0,$cd,$c8,$02,$04,$a0,$c8,$f0,$c0,$cd
!by $a0,$cd,$c0,$fd,$a0,$c8,$02,$04,$a0,$c8,$02,$04,$a0,$c8,$a0,$c8,$a0,$d9,$cd,$a0
!by $cd,$a0,$c8,$a0,$c8,$a0,$02,$04,$ed,$c0,$fd,$a0,$03,$04,$cd,$ce,$fd,$ed,$c0,$fd
!by $ed,$c0,$02,$04,$cd,$ce,$c0,$03,$04,$fd,$ed,$c0,$fd,$ed,$c0,$fd,$a0,$ed,$c0,$fd
!by $a0,$cd,$ce,$a0,$ed,$c0,$fd,$a0,$02,$04,$20,$7f,$04,$17,$12,$09,$14,$02,$04,$05
!by $0e,$20,$02,$19,$20,$02,$04,$13,$08,$01,$15,$0e,$20,$13,$0f,$15,$14,$08,$05,$12
!by $0e,$20,$5f,$04,$28,$03,$29,$31,$39,$38,$36,$20,$0d,$12,$20,$03,$08,$09,$10,$20
!by $13,$0f,$06,$14,$17,$01,$12,$05,$20,$ef,$04,$01,$2e,$0d,$0f,$12,$02,$04,$09,$13
!by $20
title:

Alles anzeigen

Assembler (Spiele-) Tutorial für C16 und Plus/4

Ähnliche Themen

Neuer Retro-Computer im 8-Bit Style

C64 Spielzeit mit Andira

PC-Umgebung, um in BASIC Spiele im 8-Bit-Stil zu schreiben

Schiebe-Puzzle Grafik sucht Umsetzung

Amiga Entwicklung und Programmierung heute wie früher

Neues Buch: Programming the Commodore 64 again

Mehr SW für den Commodore 65 bzw. Mega65

Bekommen neue Amiga Spiele zu wenig Aufmerksamkeit ?

Zu dumm für Assembler? Was Hänschen nicht gelernt..

Konstanten, Variablen, Lables & Symbole, was für ein Durcheinander! :-O