File nachladen

awsm · 20. Mai 2015

Hallo zusammen,
ich habe mir aus der Codebase64 folgendes Schnipsel gezogen, um ein File nachzuladen:

Code

load
sei
lda #$37 ;Turn kernal on
sta $01
jsr $ff81 ;Warm reset
lda #$00 ;Black border + background
sta $d020
sta $d021
;Accumulate IRQ for flashing border routine
lda #<flashload
ldx #>flashload
sta $0328
stx $0329
cli
lda #$08
ldx $ba ;Read from current disk drive present (Always use this instead of ldx #$08)
tay
jsr $ffba ;Is device present?
lda #$04 ;File length
ldx #<loadname
ldy #>loadname ;Set the load name
jsr $ffbd ;Disk drive searches/loads the loadname
lda #$00
jsr $ffd5
ldx #$08
jsr $ffc3
jsr $ffcc
jsr $ff81
jsr $a659 ;BASIC RUN start
jmp $a7ae
flashload inc $d020
dec $d020
jmp $f6fe
loadname !text"test"

Alles anzeigen

Nachgeladen und direkt gestartet werden soll also ein Programm "test", welches sich im D64 Image befindet.
Was allerdings passiert: das aufrufende Programm wird immer wieder aufgerufen (bzw immer wieder geladen, genau habe ich das noch nicht verstanden).
Hab ich irgendwas offensichtliches übersehen?

Gold Beaver · 20. Mai 2015

Das dürfte wohl an dem "jsr BASIC RUN start" liegen. Überhaupt macht der Codeschnipsel ziemlich viel neben dem eigentlichen Gelade, vergisst dafür aber beim Laden eventuelle Fehler abzufangen, und die Kommentare ergeben auch nicht wirklich Sinn, ich würd daher vielleicht lieber mit diesem didaktisch wertvolleren Beispiel anfangen

Mac Bacon · 20. Mai 2015

Nur um sicherzugehen:
-Ist das nachzuladende Programm BASIC oder Maschinensprache?
-Wird der Dateiname korrekt (d.h. PetSCII-) kodiert? Bau mal hinter dem jsr $ffd5 ein bcs load_error ein, sonst merkst Du ja gar nicht, wenn das Laden schiefgeht.

Grundsätzlich: Der Codeschnipsel ist grauenhaft. Wo die Kommentare nicht fehlen, sind sie falsch.

EDIT: Colt war mal wieder schneller.

EDIT2: Nach Konsultation von codebase: Ah, Richard Bayliss, das erklärt es. Dessen Tutorials unterbieten das Niveau von Data Becker.

awsm · 20. Mai 2015

Mit der anderen Routine hatte ich es davor erfolglos probiert. Könnte ich aber mit den neuen Erkenntnissen nochmal wagen.
Das nachzuladene Programm ist Maschinensprache mit ner Basic Startzeile.

Mac Bacon · 20. Mai 2015

Das von Colt verlinkte Beispiel erledigt nur das Laden selbst, den Aufruf von BASIC-RUN musst Du danach natürlich noch selbst machen.
Dass der Code nicht vom nachgeladenen Programm überschrieben werden sollte, hast Du bedacht?

awsm · 27. Juli 2015

So, nach ein paar weiteren Experimenten stehe ich nun wieder auf dem Schlauch.
Ich nutze nun die besser verständliche Routine von hier: http://codebase64.org/doku.php?id=base:loading_a_file

Allerdings mache ich vermutlich so einiges falsch, aber der Reihe nach. Ich will ein BASIC Programm nachladen (und natürlich auch starten), keine Ahnung ob ein JMP $0801 überhaupt funktioniert für diesen Zweck? Soweit komme ich aber eh nicht, da mir laut Errorcode immer ein File Not Found ausgegeben wird.
Ich gehe so vor: Ich kompiliere das File und füge es einem D64 hinzu, welches die Datei "abspann" bereits enthält.
Bis dahin zu kommen war schon ein Learning, aber jetzt geht's ohne einen Schubs in die richtige Richtung nicht weiter.

Code

!cpu 6502
!to "build/loader.prg",cbm ; output file
* = $0801
!byte $0d,$08,$00,$00,$9e,$20,$34,$39,$31,$35,$32
* = $c000
dec $d021
dec $d020
lda #fnameend-fname
ldx #<fname
ldy #>fname
jsr $FFBD ; call SETNAM
lda #$01
ldx $BA ; last used device number
bne skip
ldx #$08 ; default to device 8
skip ldy #$01 ; not $01 means: load to address stored in file
jsr $FFBA ; call SETLFS
lda #$00 ; $00 means: load to memory (not verify)
jsr $FFD5 ; call LOAD
bcs error ; if carry set, a load error has happened
jmp $0801
error
; Accumulator contains BASIC error code
; most likely errors:
; A = $05 (DEVICE NOT PRESENT)
; A = $04 (FILE NOT FOUND)
; A = $1D (LOAD ERROR)
; A = $00 (BREAK, RUN/STOP has been pressed during loading)
dec $d020
sta $0401 ; error code ausgeben
fname !scr "abspann"
fnameend

Alles anzeigen

Die $d020er sind nur für's schnelle Debugging drin.
Vielen Dank für Eure Hilfe.

TheRyk · 27. Juli 2015

versuch mal das hier:

Code

fname
!scr "ABSPANN"; groß geschrieben
fnameend

Steht denn bei $BA auch schon #$08 bzw die richtige Device No. drin?

awsm · 27. Juli 2015

Danke Dir. War auch meine erste Idee, aber das scheint es nicht zu sein.
Oder das ist nicht das alleinige Problem.
Wie würde denn ein korrekte BASIC Aufruf nach dem laden aussehen müssen?

enthusi · 27. Juli 2015

ein jmp $080x wird auch nicht gehen bei reinen BASIC Programmen.
Du willst ja den Basic-Interpreter damit fuettern und nicht den BasicQuelltext an die CPU weiterreichen direkt.
Da ginge zB Folgendes:

Code

jsr $e453 ; prepare BASIC pointers for RUN
jsr $a660 ;
jsr $a68e ; RUN
jmp $a7ae ;

Benutzt in meinem Mini-TurboTape-loader
http://www.codebase64.org/doku…turbotape_loader_source&s[]=turbo&s[]=tape

TheRyk · 27. Juli 2015

True Drive on/Dev Traps off (wahlweise auch umgekehrt sollte bei KERNAL Load auch gehen) und (wichtiger) richtiges .D64 image attached?

EDIT: zieh dir lieber mal Enthusis wink mit dem rein

Claus · 27. Juli 2015

Eigentlich sollte es wohl !pet und nicht !scr sein, da die Kernal-Routine PETSCII und keine Screencodes erwartet. Aber das macht glaube ich keinen Unterschied zu Ryk's Vorschlag...

awsm · 27. Juli 2015

Jetzt sind wir schon ein ganzes Stück weiter!
Ich glaube beide Fixes waren notwendig. Jetzt wird das BASIC Programm zumindest geladen (bricht, anders als sonst, allerdings mit einem OUT OF MEMORY ab).

Code

!cpu 6502
!to "build/loader.prg",cbm ; output file
* = $0801
!byte $0d,$08,$00,$00,$9e,$20,$34,$39,$31,$35,$32
* = $c000
dec $d021
dec $d020
lda #fnameend-fname
ldx #<fname
ldy #>fname
jsr $FFBD ; call SETNAM
lda #$01
ldx $BA ; last used device number
bne skip
ldx #$08 ; default to device 8
skip ldy #$01 ; not $01 means: load to address stored in file
jsr $FFBA ; call SETLFS
lda #$00 ; $00 means: load to memory (not verify)
jsr $FFD5 ; call LOAD
bcs error ; if carry set, a load error has happened
jsr $e453 ; prepare BASIC pointers for RUN
jsr $a660 ;
jsr $a68e ; RUN
jmp $a7ae ;
error
; Accumulator contains BASIC error code
; most likely errors:
; A = $05 (DEVICE NOT PRESENT)
; A = $04 (FILE NOT FOUND)
; A = $1D (LOAD ERROR)
; A = $00 (BREAK, RUN/STOP has been pressed during loading)
dec $d020
sta $0401 ; error code ausgeben
fname
!scr "ABSPANN"
fnameend

Alles anzeigen

Euch auf jeden Fall schonmal vielen Dank für die Blitzantworten!

TheRyk · 27. Juli 2015

Das OUT OF MEMORY problem hat was mit dem zu tun, was Enthusi gepostet hat

awsm · 27. Juli 2015

Hm. Seinen Code Snippet habe ich ja so eingebaut.. übersehe ich noch was anderes?

TheRyk · 27. Juli 2015

wie groß ist denn das nachzuladende file?

awsm · 27. Juli 2015

So 10 Zeilen, nix dollet eigentlich.

Unseen · 27. Juli 2015

Fehlt da nicht noch das Setzen des BASIC-Ende-Zeigers in $2d/$2e vor dem jsr $e453?

Edit: IIRC müssten zwei Befehle reichen:

Code

bcs error ; if carry set, a load error has happened
stx $2d ; Neu!
sty $2e ; Neu!
jsr $e453 ; prepare BASIC pointers for RUN

awsm · 27. Juli 2015

Das war's!!

Klasse, es läuft!
Vielen Dank an alle Beteiligten. 15 Minuten und die Sache war gelöst - kann mit kein besseres Forum vorstellen.

Hier nochmal der lauffähige Code falls später mal jemand ein ähnliches Problem hat:

Code

!cpu 6502
!to "build/loader.prg",cbm ; output file
* = $0801
!byte $0d,$08,$00,$00,$9e,$20,$34,$39,$31,$35,$32
* = $c000
dec $d021
dec $d020
lda #fnameend-fname
ldx #<fname
ldy #>fname
jsr $FFBD ; call SETNAM
lda #$01
ldx $BA ; last used device number
bne skip
ldx #$08 ; default to device 8
skip ldy #$01 ; not $01 means: load to address stored in file
jsr $FFBA ; call SETLFS
lda #$00 ; $00 means: load to memory (not verify)
jsr $FFD5 ; call LOAD
bcs error ; if carry set, a load error has happened
stx $2d ; Neu!
sty $2e ; Neu!
jsr $e453 ; prepare BASIC pointers for RUN
jsr $a660 ;
jsr $a68e ; RUN
jmp $a7ae ;
error
; Accumulator contains BASIC error code
; most likely errors:
; A = $05 (DEVICE NOT PRESENT)
; A = $04 (FILE NOT FOUND)
; A = $1D (LOAD ERROR)
; A = $00 (BREAK, RUN/STOP has been pressed during loading)
dec $d020
sta $0401 ; error code ausgeben
fname
!scr "ABSPANN"
fnameend

Alles anzeigen

Zaadii · 27. Juli 2015

Super, ich bin grad an nem Projekt, in dem ich das auch brauchen kann.
Eigentlich müste man damit ein beliebiges PRG nachladen können und nicht nur basic, da ja ein nicht basic prg ja einen sys befehl am beginn stehen hat, der ja auch basic ist.
Oder liege ich da falsch?

TheRyk · 27. Juli 2015

Wenn du dein Maschinensprache Programm bei $C000 beginnen lässt, wäre es kontraproduktiv, eine BASIC-SYS-Zeile bei $0801 mit abuzuspeichern.

Du würdest die KERNAL Load Routine nutzen mit Ziel $C000 und am Ende dann einfach JMP/JSR $C000 machen nach dem Ladevorgang

File nachladen

Ähnliche Themen

1541 "Ultimate" Infos & Fragen

T64 to Magic Desk Projekt

ndefpack

Easyflash1CR

GHOST VALLEY - Das neue TSB-BASIC-Spiel für den C64 ist da!

WiC64 PHP Directory Example

File im Assembler nachladen

Bytes aus Dateien schneller auslesen

In den Speicher gucken und verstehen / Sachen ändern