zufallszahlen und 16-bit zahlen ausgeben ??

alectronix · 16. März 2005

Hallo Leute,

so, nun bin ich wieder etwas drin in ASM , bei meine ersten kleinen Projekt flimmerts auch schon etwas auf dem Schirm, man kann was mit dem Joystick steuern etc.

Zwei Sachen find ich nicht raus:

1.) Wie kann ich eine Zufallszahl zwischen $00 und $FF erzeugen?

2.) Wie kann ich eine 16-bit oder noch größere Zahl auf dem Bildschirm ausgeben? Natürlich soll sie nicht HEX sondern dezimal ausgegeben werden. Wie ich sie hochzählen und im Speicher in HEX ablegen kann weiß ich, aber wie bekomme ich sie auf den Schirm? Soll ne Score Anzeige werden ...

Danke für Tipps!
Alex

Courage · 16. März 2005

Also um Zufallszahlen in Assembler zu generieren habe ich schon unzählige Varianten gehört und erprobt. Die Sache über den SID, der angeblich sogenanntes "Weißes Rauschen" erzeugen soll, was absolutem Zufall gleichkäme klappte bei mir nie so gut und ist schwer zu machen, wenn nebenbei Sound düdelt.

Naja, lange Rede kurzer Sinn. Die besten Ergebnisse hatte ich bisher mit folgender Routine:
lda $dc04
eor $dc05
eor $dd04
adc $dd05
eor $dd06
eor $dd07

Der zufällige Wert steht dann im Akku.
Das soll übrigens die Gleiche sein, wie sie in Boulder Dash für den Schleim verwendet wird.

Zur zweiten Frage kann ich leider auch nicht so viel sagen! (Um-)Rechnen und Assembler habe ich zum Glück bisher immer irgendwie umgehen können!

alectronix · 17. März 2005

coole Sache, vielen Dank!

Thomas H · 17. März 2005

Hallo

Zitat

Original von alectronix

...

2.) Wie kann ich eine 16-bit oder noch größere Zahl auf dem Bildschirm ausgeben? Natürlich soll sie nicht HEX sondern dezimal ausgegeben werden. Wie ich sie hochzählen und im Speicher in HEX ablegen kann weiß ich, aber wie bekomme ich sie auf den Schirm? Soll ne Score Anzeige werden ...

Danke für Tipps!
Alex

Alles anzeigen

Eine vorzeichenlose 16 bit Integer sollte sich mit

Lobyte Integer -> X-Register
Hibyte Integer -> Abkku
jsr $bdcd

auf dem Bildschirm darstellen lassen.

Sind es andere, größere Integer kannst Du z.B. eine 32 bit Integer in zwei
16 bit Integer zerlegen, also quasi in loword und hiword.
Dann transferierst Du hiword in eine Fließkommazahl, multipizierst sie mit 2^16
und addiest dann die ebenfalls umgewandelte loword dazu.
Diese Fließkommazahl kannst du dann via jsr $AABC auf dem Bildschirm darstellen.

Alternativ kannst Du mittels BCD-Modus die Hexzahl
via bitschieberei und BCD-Addition in eine BCD-Zahl umwandeln,
die nibbels isolieren, in die "pokewerte" der Zahlensymbole umrechnen und direkt in den Videoram schreiben.

Falls Du wissen möchtest wie das geht, kannst du in der Input64 Assemblerschule
nachlesen, oder falls Du interesse hast, kann ich dir den entsprechenden Teil der Source eines kleinen Matheprogramms schicken, das mit 24bit Integer arbeitet.

Gruß Thomas

tecM0 · 4. August 2005

Zitat

Original von Thomas H
Falls Du wissen möchtest wie das geht, kannst du in der Input64 Assemblerschule
nachlesen, oder falls Du interesse hast, kann ich dir den entsprechenden Teil der Source eines kleinen Matheprogramms schicken, das mit 24bit Integer arbeitet.

Gruß Thomas

ich hätte interesse da ich im moment vor genau dem selben problem stehe :baby:

HILFE!

gruss,
tecM0

GoDot · 4. August 2005

Zitat

Original von alectronix
1.) Wie kann ich eine Zufallszahl zwischen $00 und $FF erzeugen?

Auch, wenn manche das nicht hinkriegen, hier zur Vollständigkeit die Methode mit dem SID-Rauschen wie GoDot das macht (und da funktioniert's, es wird damit das Noise-Dithering erzeugt):

lda #$80
sta $d418 ; Filter aus
sta $d40e
sta $d40f ; Oszillator 3 vorbesetzen
lda #0
sta $d412 ; Wellenform aus, Steuerbits aus
lda #$81
sta $d412 ; Rauschen an, KEY-Bit an (Lautstärke aktivieren)

Später holst du dir dann deinen Bytewert aus dem Register $d41b (das ist das Rauschen-Register des Oszillator 3).

lda $d41b ; Zufallswert

Wie gesagt, in GoDot funktioniert das, wie jeder sich überzeugen kann (irgendein buntes Bild sollte im Speicher sein):

Im Fenster "Screen Controls" zuerst von "Multi" auf "Hires" umschalten, dann die Anzahl Farben im Gadget darunter auf 2 einstellen ("Colors: 2"). Zum Einstellen des Ditherings danach im Fenster "Color Controls" zweimal ins Gadget "Dith" klicken (auf der linken Seite) bis "Noise" erscheint. Und schließlich Rendern über das Gadget "Palette". Dort "Default" einstellen (damit die Farben schwarz und weiß verwendet werden) und mit dem Display-Button das auf Rauschen umgerechnete Bild anzeigen. Die Grundeinstellung des Rauschens ist sehr grob, wenn du mehr erkennen können willst, erhöhst du unter "Balancing"den Kontrast auf 5 oder noch viel mehr.

Arndt

tecM0 · 4. August 2005

danke danke! zufallszahlen waren aber geklärt. ausserdem wenn mukke
läuft wird das bestimmt nix mit dem SIDgerausche.

und wie bekomme ich jetzt eine 16bit zahl dezimal auf den screen?

T.

GoDot · 4. August 2005

Zitat

Original von tecM0
zufallszahlen waren aber geklärt.

Genau lesen! Was sagte ich? "...zur Vollständigkeit die Methode..."

Zitat

und wie bekomme ich jetzt eine 16bit zahl dezimal auf den screen?

Highbyte im Akku, Lowbyte in x:

sta $62
stx $63 ; (!)
ldx #$90
sec
jsr $bc49
jsr $bddf

Ergebhis liegt an $0100 und sollte mit $00 enden (bin nicht mehr sicher, so aus dem hohlen Kopf...)

Arndt

tecM0 · 4. August 2005

nein, ohne ROM ... muss doch auch gehen !?
für demo/game zwecke ist das nix

T.

tecM0 · 4. August 2005

so... google is your (my) friend ... http://groups-beta.google.com/…g/208250610a94613b?hl=en&

Code

;You can translate 16bit number in ascii by subtracting it's 10k, 1k,
;100, 10 and 1's. This is one of the ways. 16bit is <= to 5 digit
;decimal.
;Put the constants of 10k, 1k, 100, 10 and 1 in sequential 16bit
;locations like:
;put the ascii leading zeroes and binary 0 after that.
wawa
lda thehex
sta tdsrc
lda thehex+1
sta tdsrc+1
hextodec
ldy #$00
lda #$30
td1 sta tddst,y
iny
cpy #$05
bne td1
lda #$00
sta tddst,y
ldy #$00
ldx #$00
td3 lda tdsrc
sec
sbc tdlkup,y
pha
lda tdsrc+1
sbc tdlkup+1,y
bcc td2
sta tdsrc+1
pla
sta tdsrc
inc tddst,x
jmp td3
td2 iny
iny
inx
cpx #$05
bne td3
;rts
;degug_gedöns
;anzeigen
ldx #0
yxc
lda tddst,x
sta $0400,x
inx
bne yxc
;hochzählen
inc thehex
bne yxcv
inc thehex+1
yxcv
inc $d020
jmp wawa
tdlkup !byte $10,$27,$e8,$03,$64,$00,$0a,$00,$01,$00
tdsrc !byte $00,$00
tddst !byte 0,0,0,0,0,0
thehex !byte $01,$01

Alles anzeigen

so..je mehr 9er enthalten sind um so langer dauert der spass.

gibts einen anderen/besseren weg...ohne ROM?

tecM0

Hoogo · 4. August 2005

Die "übliche" Divisionsroutine durch 10 gibt ja das Ergebnis und einen Rest zurück. Der Rest ist die unterste Ziffer. Und das wiederholt man dann, bis das Divisionsergebnis 0 ist.

Code

!to "zahlaus.prg"
*=$c000
; irgendeine Zahl in $fa/b. Sie wird bei der Ausgabe letztendlich zerstört
lda#<9999
sta $fa
lda#>9999
sta $fb
s_zahlAusgeben
; 5 Stellen sind zu erwarten und werden von der untersten an geliefert.
ldy#5
.eineZiffer
; $fa/b = $fa/b durch 10, Rest im Akku
; 16 Bit werden vom obersten an in den Akku geschoben
ldx#16
clc
lda#0
.einBit rol $fa
rol $fb
rol
cmp#10
bcc .keinUeberlauf
sbc#10
.keinUeberlauf dex
bne .einBit
; Alle Ziffern sind verarbeitet, der Carry enthält noch das letzte Bit des Ergebnisses
rol $fa
rol $fb
; Akku ist der Rest, Ziffer zur Ausgabe
ora#48
sta 1024,y
; 5 Ziffern durch?
dey
bne .eineZiffer
rts

Alles anzeigen

tecM0 · 4. August 2005

danke hoogo,

habe es gerade ausprobiert und es funktioniert 100%ig.

gruss,
tecM0

EDIT:

ich habe mal beide zusammengebaut. die erste routine braucht nicht immer die
gleiche zeit... deine hat immer die gleiche laufzeit .... hmmm

Code

;---------------------------------------
*= $1000
;---------------------------------------
sei
gugu
; irgendeine Zahl in $fa/b. Sie wird bei der Ausgabe letztendlich zerstört
lda thehex
sta $fa
lda thehex+1
sta $fb
lda #80
cmp $d012
bne *-3
inc $d020
; 5 Stellen sind zu erwarten und werden von der untersten an geliefert.
ldy#5
todl
; $fa/b = $fa/b durch 10, Rest im Akku
; 16 Bit werden vom obersten an in den Akku geschoben
ldx #16
clc
lda #0
tod1b
rol $fa
rol $fb
rol
cmp #10
bcc tod2b
sbc #10
tod2b
dex
bne tod1b
; Alle Ziffern sind verarbeitet, der Carry enthält noch das letzte Bit des Ergebnisses
rol $fa
rol $fb
; Akku ist der Rest, Ziffer zur Ausgabe
ora #48
sta 1024,y
; 5 Ziffern durch?
dey
bne todl
dec $d020
;You can translate 16bit number in ascii by subtracting it's 10k, 1k,
;100, 10 and 1's. This is one of the ways. 16bit is <= to 5 digit
;decimal.
;Put the constants of 10k, 1k, 100, 10 and 1 in sequential 16bit
;locations like:
;put the ascii leading zeroes and binary 0 after that.
lda thehex
sta tdsrc
lda thehex+1
sta tdsrc+1
lda #150
cmp $d012
bne *-3
inc $d020
hextodec
ldy #$00
lda #$30
td1 sta tddst,y
iny
cpy #$05
bne td1
lda #$00
sta tddst,y
ldy #$00
ldx #$00
td3 lda tdsrc
sec
sbc tdlkup,y
pha
lda tdsrc+1
sbc tdlkup+1,y
bcc td2
sta tdsrc+1
pla
sta tdsrc
inc tddst,x
jmp td3
td2 iny
iny
inx
cpx #$05
bne td3
;rts
dec $d020
;degug_gedöns
;anzeigen
ldx #5
yxc
lda tddst,x
sta $0429,x
dex
bpl yxc
;hochzählen
inc thehex
bne yxcv
inc thehex+1
yxcv
jmp gugu
tdlkup !byte $10,$27,$e8,$03,$64,$00,$0a,$00,$01,$00
tdsrc !byte $00,$00
tddst !byte 0,0,0,0,0,0
thehex !byte $00,$00

Alles anzeigen

Hoogo · 4. August 2005

Ich mein bei td2 fehlt noch ein PLA

tecM0 · 4. August 2005

kann man...muss aber nicht, da von td2 ja eh möglicherweise zu td3
gesprungen wird und da steht "lda tdsrc"

T.

Hoogo · 5. August 2005

What???
Wenn ich das richtig sehe, lässt die Routine je ausgegebener Ziffer ein Byte auf dem Stapel zurück, und nach alter Väter Sitte sollten die da eigentlich nicht liegen bleiben. So funktioniert ja kein RTS mehr, und eigentlich ist sowas doch eher ein Unterprogramm...

tecM0 · 5. August 2005

ufff...da hast du natürlich recht...sorry.

gruss,
tecM0

Dow Jones · 5. August 2005

Und hier kommt noch ein Kandidat für die dezimale Ausgabe von 16-Bit-Zahlen. Ziemlich lang diesmal, aber dafür recht fix. Der Algorithmus findet die jeweils richtige Ziffer mittels binärer Suche.

Code

zahl >= 5?
ja {
zahl >= 7?
ja {
zahl >=8?
ja {
zahl >= 9?
ja { print 9 }
nein { print 8 }
}
nein { print 7 }
}
nein {
zahl >= 6?
ja { print 6 }
nein { print 5}
}
}
nein {
zahl >= 2?
ja {
zahl >= 3?
ja {
zahl >= 4?
ja { print 4 }
nein { print 3}
}
nein { print 2 }
}
nein {
zahl >= 1?
ja { print 1 }
nein { print 0 }
}
}

Alles anzeigen

Implementiert (mit ein paar kleinen Optimierungen) sieht das so aus:

Code

; gewünschte zahl in $02/03
ldx #0 ; stelle, 0-4, 0=10.000er, 4=1er
z0_9 sec
lda $02
sbc lowtab5,x
lda $03
sbc hightab5,x
bcc z0_4
z5_9 ; sec ; unnoetig, da zuvor bcc
lda $02
sbc lowtab7,x
sta *+9
lda $03
sbc hightab7,x
ora #$00
beq z5_6
bcs z7_9
z5_6 sec
lda $02
sbc lowtab6,x
sta $02
lda $03
sbc hightab6,x
sta $03
bcs z6
z5 clc
lda $02
adc lowtab1,x
sta $02
lda $03
adc hightab1,x
sta $03
lda #$35
bne e
z6 lda #$36
bne e
z7_9 ; sec
lda $02
sbc lowtab8,x
lda $03
sbc hightab8,x
bcc z7
z8_9 ; sec
lda $02
sbc lowtab9,x
sta $02
lda $03
sbc hightab9,x
sta $03
bcc z8
z9 lda #$39 ; screencode fuer ziffer 9
bne e ; unbedingter sprung
z8 clc
lda $02
adc lowtab1,x ; wir hatten ja schon 9 abgezogen,
sta $02 ; daher mussen wir jetzt wieder 1 aufaddieren
lda $03
adc hightab1,x
sta $03
lda #$38
bne e
z0_4 sec
lda $02
sbc lowtab2,x
lda $03
sbc hightab2,x
bcc z0_1
z2_4 lda $02
sbc lowtab3,x
lda $03
sbc hightab3,x
bcc z2
z3_4 lda $02
sbc lowtab4,x
sta $02
lda $03
sbc hightab4,x
sta $03
bcc z3
z4 lda #$34
bne e
z7 sec
lda $02
sbc lowtab7,x
sta $02
lda $03
sbc hightab7,x
sta $03
lda #$37
; bne e
e sta $0451,x ; der teil steht hier
inx ; mittendrin damit
cpx #04 ; er per branch
beq end ; erreichbar bleibt
jmp z0_9
z3 clc
lda $02
adc lowtab1,x
sta $02
lda $03
adc hightab1,x
sta $03
lda #$33
bne e
z2 sec
lda $02
sbc lowtab2,x
sta $02
lda $03
sbc hightab2,x
sta $03
lda #$32
bne e
z0_1 sec
lda $02
sbc lowtab1,x
lda $03
sbc hightab1,x
bcc z0
z1 sec
lda $02
sbc lowtab1,x
sta $02
lda $03
sbc hightab1,x
sta $03
lda #$31
bne e
z0 lda #$30
bne e
end clc
lda $02
adc #$30
sta $0451,x
rts
lowtab0 !byte <00000, <0000, <000, <00, <0
lowtab1 !byte <10000, <1000, <100, <10, <1
lowtab2 !byte <20000, <2000, <200, <20, <2
lowtab3 !byte <30000, <3000, <300, <30, <3
lowtab4 !byte <40000, <4000, <400, <40, <4
lowtab5 !byte <50000, <5000, <500, <50, <5
lowtab6 !byte <60000, <6000, <600, <60, <6
lowtab7 !byte $ff, <7000, <700, <70, <7
lowtab8 !byte $ff, <8000, <800, <80, <8
lowtab9 !byte $ff, <9000, <900, <90, <9
hightab0 !byte >00000, >0000, >000, >00, >0
hightab1 !byte >10000, >1000, >100, >10, >1
hightab2 !byte >20000, >2000, >200, >20, >2
hightab3 !byte >30000, >3000, >300, >30, >3
hightab4 !byte >40000, >4000, >400, >40, >4
hightab5 !byte >50000, >5000, >500, >50, >5
hightab6 !byte >60000, >6000, >600, >60, >6
hightab7 !byte $ff, >7000, >700, >70, >7
hightab8 !byte $ff, >8000, >800, >80, >8
hightab9 !byte $ff, >9000, >900, >90, >9

Alles anzeigen

Und hier die Stats:

Tecmos Routine
Minimale Rasterzeit in Zeilen: 4
Maximale Rasterzeit in Zeilen: 36
Durchschnittliche Rasterzeit in Zeilen: 19,989
Länge in Bytes: 68

Hoogos Routine
Minimale Rasterzeit in Zeilen: 33
Maximale Rasterzeit in Zeilen: 33
Durchschnittliche Rasterzeit in Zeilen: 33
Länge in Bytes: 32

Dow Jones Routine
Minimale Rasterzeit in Zeilen: 5
Maximale Rasterzeit in Zeilen: 8
Durchschnittliche Rasterzeit in Zeilen: 6,302
Länge in Bytes: 379

tecM0 · 5. August 2005

hehe...der DJ is the master!

ich denke hoogos routine ist die mit der festen rasterzeit, oder?
und "meine" ist es ja auch nicht weil ich sie erstens bei google_groups
gefunden habe und zweitens unfähig bin.

nichtschlechtnichtschlecht! für zeitkritische sachen also DJ's verwenden,
wenn man die 360 bytes noch frei hat!

gruss,
tecM0

PS: solcher "coderChats" mag ich ... mehr davon!

Dow Jones · 5. August 2005

Um nochmal auf die Zufallszahlen zurückzukommen - wie gut sind denn die Zufallszahlen, die mittels Timer-EOR und Sid-Rauschen erzeugt werden? Hat das mal jemand untersucht? Für Spiele Noise-Dithering mag das ja reichen, aber für ernsthafte Anwendungen scheint mir das unbrauchbar. Da würde ich wohl eher diesen seltsamen Generator von White Flame hernehmen (16 Bit Version) und vom Ergebnis nur die jeweils unteren 8 Bit benutzen.
Wie erzeugt denn die RND-Funktion im Basic ihre Zahlen?!

Dow Jones · 5. August 2005

Zitat

Original von tecM0
hehe...der DJ is the master!

ich denke hoogos routine ist die mit der festen rasterzeit, oder?
und "meine" ist es ja auch nicht weil ich sie erstens bei google_groups
gefunden habe und zweitens unfähig bin.

Stimmt, da habe ich die beiden vertauscht. Hab's gerade geändert, jetzt stimmt's.

Tags