V-Scroll Problem

cbmhardware · 18. April 2006

Ich spiele im Moment mit einem Listing aus dem 64-Intern rum. Ich habe das mal etwas umgebaut und die dollsten Kloepse ausgelassen.

Nun kann ich am Ende aber nicht das Hi-Byte erhoehen, damit auch mal mehr als 256 Byte reingescrollt werden.

Was mache ich falsch ?

Code

!to "d011_1.prg"
*=$1000
vcr = $d011
raster = $d012
count =$fa
lda #00
sta $d020
sta $d021
sta count
j1 sei
ldx #7
lda vcr
ora #7
sta vcr
lp1 jsr soft
dex
bne lp1
lp2 lda vcr
bpl lp2
lp3 lda vcr
bmi lp3
r0 lda #$6b
cmp raster
bne r0
ldy #40
lp6 lda 1064,y
sta 1024,y
lda 1104,y
sta 1064,y
lda 1144,y
sta 1104,y
lda 1184,y
sta 1144,y
lda 1224,y
sta 1184,y
lda 1264,y
sta 1224,y
lda 1304,y
sta 1264,y
lda 1344,y
sta 1304,y
lda 1384,y
sta 1344,y
lda 1424,y
sta 1384,y
lda 1464,y
sta 1424,y
lda 1504,y
sta 1464,y
lda 1544,y
sta 1504,y
lda 1584,y
sta 1544,y
lda 1624,y
sta 1584,y
lda 1664,y
sta 1624,y
lda 1704,y
sta 1664,y
lda 1744,y
sta 1704,y
lda 1784,y
sta 1744,y
lda 1824,y
sta 1784,y
lda 1864,y
sta 1824,y
lda 1904,y
sta 1864,y
lda 1944,y
sta 1904,y
lda 1984,y
sta 1944,y
dey
beq next
jmp lp6
next ldy #40
lp10 lda $1200,y
sta $07c0,y
dey
lda lp10+1
cmp #$00
beq uphi
bne again
uphi ; inc lp10+2
again cpy #0
bne lp10
lda lp10+1
adc #40
sta lp10+1
lda vcr
ora #7
sta vcr
jmp j1
soft lda raster
cmp #$fa
bne soft
dec vcr
rts
rts
*=$1200
buffer
!scr " ein test 1 "
!scr " ein test 2 "
!scr " ein test 3 "
!scr " ein test 4 "
!scr " ein test 5 "
!scr " ein test 6 "
!scr " ein test 7 "
!scr " ein test 8 "
!scr " ein test 9 "
!scr " ein test 10 "
!scr " ein test 11 "
!scr " ein test 12 "
!scr " ein test 13 "
!scr " ein test 14 "
!scr " ein test 15 "
!scr " ein test 16 "
!scr " ein test 17 "
!scr " ein test 18 "
!scr " ein test 19 "

Alles anzeigen

Courage · 18. April 2006

Dumme Frage: Das Semikolon in Zeile 120 haste schon weggelassen, oder?

cbmhardware · 18. April 2006

Ja. Dann wird aus $1200 irgendetwas mit $3A.. . Koennte auch etwas weniger sein. War der erste Wert nach Griff auf ALT+M im Vice.

Ich muss mal einen komplett anderen Ansatz versuchen. Nochmal.

Ist zum Verzweifeln. Bin heute scheinbar zu bloede..

Michael

Courage · 18. April 2006

Jo, würde 115-120 rausnehmen.

Ab 126 dann wie folgt:

clc
lda lp10+1
adc #40
sta lp10+1
bcc Rücksprung ohne Erhöhung
inc lp10+2

Courage · 18. April 2006

Denn in Zeile 115-120 erhöhst Du ja jedes mal, nachdem Du lediglich y um einen runtergezählt hast,
lp10+2 um 1. Also erst die komplette Zeile reinkopieren und dann prüfen, ob lp10+2 erhöht werden muß.

cbmhardware · 18. April 2006

Jou, Problem geloest. Das mit ADC und Uebertrag hatte mir gefehlt. Daher habe ich in der Schleife rumgewurschtelt.

Danke !,
Michael

Code

!to "d011_1.prg"
*=$1000
vcr = $d011
raster = $d012
lda #00
sta $d020
sta $d021
j1 sei
ldx #7
lda vcr
ora #7
sta vcr
lp1 jsr soft
dex
bne lp1
lp2 lda vcr
bpl lp2
lp3 lda vcr
bmi lp3
r0 lda #$6b
cmp raster
bne r0
ldy #40
lp6 lda 1064,y
sta 1024,y
lda 1104,y
sta 1064,y
lda 1144,y
sta 1104,y
lda 1184,y
sta 1144,y
lda 1224,y
sta 1184,y
lda 1264,y
sta 1224,y
lda 1304,y
sta 1264,y
lda 1344,y
sta 1304,y
lda 1384,y
sta 1344,y
lda 1424,y
sta 1384,y
lda 1464,y
sta 1424,y
lda 1504,y
sta 1464,y
lda 1544,y
sta 1504,y
lda 1584,y
sta 1544,y
lda 1624,y
sta 1584,y
lda 1664,y
sta 1624,y
lda 1704,y
sta 1664,y
lda 1744,y
sta 1704,y
lda 1784,y
sta 1744,y
lda 1824,y
sta 1784,y
lda 1864,y
sta 1824,y
lda 1904,y
sta 1864,y
lda 1944,y
sta 1904,y
lda 1984,y
sta 1944,y
dey
beq next
jmp lp6
next ldy #40
lp10 lda $1200,y
sta $07c0,y
dey
bne lp10
lda lp10+1
adc #40
sta lp10+1
bcc goon
inc lp10+2
goon lda vcr
ora #7
sta vcr
jmp j1
soft lda raster
cmp #$fa
bne soft
dec vcr
rts
*=$1200
buffer
!scr " dank courage geht es nun :) "
!scr " 2 "
!scr " 3 "
!scr " 4 "
!scr " ein test 5 "
!scr " ein test 6 "
!scr " ein test 7 "
!scr " ein test 8 "
!scr " ein test 9 "
!scr " ein test 10 "
!scr " ein test 11 "
!scr " ein test 12 "
!scr " ein test 13 "
!scr " ein test 14 "
!scr " ein test 15 "
!scr " ein test 16 "
!scr " ein test 17 "
!scr " ein test 18 "
!scr " ein test 19 "
!scr " ein test 20 "

Alles anzeigen

cbmhardware · 18. April 2006

Ich moechte das nun noch "enthampeln".

Duerfte doch mit Double Buffering gehen ? :

1. Pixel scrollen im sichtbaren Screen
2. heimlich den hardscroll im unsichtbaren Speicher
3. einschalten und wieder zurueck zum ersten Screen
4. loop zu 1.

Wuerde ich das so richtig machen ?

Michael

Roland · 18. April 2006

ehmm...

würde das folgendermassen beschreiben:

1. pixel scrollen/anzeigen in screen 1
2. wärenddessen hardscrollen in screen 2
3. wenn 8 pixel in screen 1 gescrollt sind (und der hardscroll in screen 2 fertig ist) -> umschalten auf screen 2
4. pixel scrollen/anzeigen in screen 2
5. wärenddessen hardscrollen in screen 1
6. wenn 8 pixel in screen 2 gescrollt sind (und der hardscroll in screen 1 fertig ist) -> umschalten auf screen 1
7 goto 1

cbmhardware · 18. April 2006

Prima, danke, so hatte ich das auch gemeint. Im Prinzip wird dann immer im nicht sichtbaren Bereich der hardscroll ausgefuehrt.

Habe noch keine Idee wie ich das machen soll. Bevor ich ergraut bin, moechte ich aber mal ruckelfrei in beide Richtungen scrollen koennen.

Michael

Roland · 18. April 2006

naja... ist relativ einfach, wenn es eine kontinuierliche bewegung in eine richtung ist.
da kann man den hardscroll ja auch einfach über mehrere frames verteilen (wenn nicht all zu schnell gescroll wird).

wenn allerdings noch nicht klar ist, wohin die reise geht, oder mitten in der bewegung umgedreht wird braucht es halt ein bissle mehr inteligenz

wenn man dann allerdings noch die farben mitscrollen will, muss man aufpassen, da das ja nicht mit doublebuffering gemacht werden kann (gibt ja nur ein color-ram).

cbmhardware · 19. April 2006

Farbe muss ich mir nicht antun.;) Wenn ich erstmal etwas Text scrollen kann ist das ok.
Habe es nicht so mit diesen "Haken und Oesen"-Grafikchips.

Ich habe mal "double-buffering" eingebaut. Beim Start scrollt manchmal noch Gruetze raus, obwohl beide Screenrams geloescht wurden.
In der linken oberen Ecke hampelt $0400 , bzw. $3c00 etwas rum, aber gesamt sieht das schon viel besser aus.

Vieleicht hat jemand eine Idee zu den bugs ?

Source passte nicht mehr in einen Beitrag, daher als Link : http://www.cbmhardware.de/test/softi.txt

Michael

Roland · 19. April 2006

hmm... beim ersten schnellen überblick frage ich mich, wieso du in der "rewash" routine was in $c300 schreibst?
und das $3b00 sollte wohl eher $3c00 sein...oder?

cbmhardware · 19. April 2006

Ja, danke, hatte ich heute schon gemerkt. Kleiner naechtlicher Dreher.

Kann man das noch irgendwie optimieren ?

Michael

Roland · 19. April 2006

man kann (fast) alles optimieren...

kommt halt auch darauf an, auf was?
speed? grösse? lesbarkeit?, witzige labels?

cbmhardware · 19. April 2006

Zitat

Original von Roland
man kann (fast) alles optimieren...

kommt halt auch darauf an, auf was?
speed? grösse? lesbarkeit?, witzige labels?

Ja, ich nehme alles.

Speziell dachte ich Groesse und ruckelfreies (sehr) langsames scrollen.

Michael

Roland · 19. April 2006

ehm... hab mir die routine eben nochmal angeschaut...

wieso hat das ding eigentlich eine irq routine???
vorallem wird die nicht wirklich im sinne einer irq routine verwendet.

da wird EINMAL der irq aufgerufen und dann NIE WIEDER verlassen!!!
(ist wirklich ein komisches gewurschtel mit dem wait for raster..usw..)

Da kannst du das mit dem irq gleich sein lassen

Vielleicht sollte da mal zuerst eine saubere kleine irq-routine her, damit
du das prinzip eines irqs verstehst...oder?

cbmhardware · 19. April 2006

Zitat

Original von Roland
ehm... hab mir die routine eben nochmal angeschaut...

wieso hat das ding eigentlich eine irq routine???
vorallem wird die nicht wirklich im sinne einer irq routine verwendet.

da wird EINMAL der irq aufgerufen und dann NIE WIEDER verlassen!!!
(ist wirklich ein komisches gewurschtel mit dem wait for raster..usw..)

Da kannst du das mit dem irq gleich sein lassen

Alles anzeigen

Das war nur ein Versuchballon. Hatte ich nicht wieder rausgenommen. Ist so natuerlich Kaese.

Das mit dem Warten auf den Rasterstrahl muss aber sein. Wenn der sich in der Mitte befindet, man dann den Scroll durchfuehrt, kannst Du Dir den Rest sicher denken. Das habe ich so aus dem 64er-Intern uebernommen.

Zitat

Vielleicht sollte da mal zuerst eine saubere kleine irq-routine her, damit
du das prinzip eines irqs verstehst...oder?

Ich wollte das mal mit einem SID zugleich ablaufen lassen, um zu sehen, wie sich das Ganze dann verhaelt.

Es gibt keine vernuenftige Doku zu diesem Thema fuer einen fast 25 Jahre alten Rechner. Da muss man sich etwas zusammenwurschteln.

Michael

Roland · 19. April 2006

naja.... genau dafür ist ein raster-irq ja da, damit du eben nicht auf einen bestimmten wert im rasterregister rumwarten musst um nicht in der mitte des screens ein scroll durchzuführen...

...du sagst dem irq: "starte bitte in rasterzeile x" ...und der ruft dann in zeile x dein programm auf

und das es für diesen 25 jahre alten computer keine doku geben soll...

cbmhardware · 19. April 2006

Zitat

Original von Roland
und das es für diesen 25 jahre alten computer keine doku geben soll...

Ich besitze bestimmt 2-300 Buecher fuer den C64. Davon sind vieleicht 10 zum Thema Assembler.
Da stehen dann auch die ganz banalen Sachen drin. Die Sources sind nach heutigem Stand mehr als ueberholt. Grafikmodis und andere Spielereien nach 1990 gab es damals natuerlich noch nicht.
Wenn man damit anfangen moechte, kann man die paar Buecher nur noch zum Nachschlagen von Tokens verwenden, oder damit nebenbei die Bude heizen.

Da bleiben dann noch die Schnipsel und wenigen brauchbaren Seiten im Web. Und dann faengt man an zu wurschteln.

Michael

Roland · 19. April 2006

ich hau hier mal kurz ein schmipsel hin, wie es auch gehen kann (ohne double buffering und nicht sehr optimiert... aber es geht)

Code

1000 sei
1001 lda #01
1003 sta d01a
1006 sta dc0d
1009 lda #1b
100b sta d011
100e lda #ff
1010 sta d012
1013 lda #21
1015 sta 0314
1018 lda #10
101a sta 0315
101d cli
101e jmp 101e
1021 lda #03
1023 sec
1024 sbc #01 (hier kannst du die scrollspeed von 1 - 8 einstellen)
1026 and #07
1028 sta 1022
102b ora #10
102d sta d011
1030 bcs 1083
1032 ldx #00
1034 lda 0428,x
1037 sta 0400,x
103a inx
103b bne 1034
103d lda 0528,x
1040 sta 0500,x
1043 inx
1044 bne 103d
1046 lda 0628,x
1049 sta 0600,x
104c inx
104d bne 1046
104f lda 0728,x
1052 sta 0700,x
1055 inx
1056 cpx #c0
1058 bne 104f
105a ldx #27
105c lda e000,x
105f sta 07c0,x
1062 dex
1063 bpl 105c
1065 lda 105d
1068 ldy 105e
106b clc
106c adc #28
106e bcc 1071
1070 iny
1071 cpy #ef
1073 bne 107d
1075 cmp #f0
1077 bne 107d
1079 lda #00
107b ldy #e0
107d sta 105d
1080 sty 105e
1083 inc d019
1086 jmp ea81

Alles anzeigen

so.... kann man in hinsicht von speed natürlich noch optimieren...
...geht ja nur darum, dass es mal bugfree läuft.
text ist quasi auf $e000 eingestellt (damit man halt was sieht )
ansonsten erklährt sich hoffentlich alles von selbst...

ich hoffe mal bloss, dass kein tipp/denkfehler drin ist, da ich das einfach mal aus dem kopf gemacht habe.... :baby:

Tags